build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' apply false
    id 'io.spring.dependency-management'
}

allprojects {
    group = projectGroup
    version = applicationVersion
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'

    java {
        sourceCompatibility = '17'
    }

    repositories {
        mavenCentral()
    }
}

def springProjects = [':producer', ':transformer-server', ':consumer']

springProjects.each {projectPath ->
    project(projectPath) {
        dependencies {
            // start spring boot web
            implementation 'org.springframework.boot:spring-boot-starter-web'

            // start spring cloud stream
            implementation 'org.springframework.cloud:spring-cloud-stream'

            //start spring cloud kafka
            implementation 'org.springframework.cloud:spring-cloud-stream-binder-kafka'

            //start spring cloud rabbit-mq
            implementation 'org.springframework.cloud:spring-cloud-stream-binder-rabbit'

            //spring cloud-aws-starter
            implementation 'io.awspring.cloud:spring-cloud-aws-starter-secrets-manager'

            testImplementation 'org.springframework.boot:spring-boot-starter-test'
            testImplementation 'org.springframework.cloud:spring-cloud-stream-test-binder'

            compileOnly 'org.projectlombok:lombok'
            annotationProcessor 'org.projectlombok:lombok'
        }

        dependencyManagement {
            imports {
                mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
                mavenBom "io.awspring.cloud:spring-cloud-aws-dependencies:${springCloudAwsVersion}"
            }
        }

        tasks.named('test') {
            useJUnitPlatform()
        }
    }
}