build.gradle

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "com.github.rodm:gradle-teamcity-plugin:1.4"
    }
}

apply plugin: 'java'
apply plugin: 'com.github.rodm.teamcity-server'

group 'org.jetbrains.teamcity'
version = "$System.env.BUILD_NUMBER"
if (version.length() == 0) {
    version = "SNAPSHOT"
}

dependencies {
    implementation 'com.google.code.gson:gson:2.3.1'
    implementation 'org.apache.httpcomponents:httpclient:4.5.2'
    testImplementation 'org.springframework:spring-test:4.3.2.RELEASE'
    testImplementation 'org.mockito:mockito-core:2.1.0-RC.1'
    provided(group: 'org.jetbrains.teamcity', name: 'oauth', version: "${TeamCityVersion}")
}

test {
    useTestNG()
}

ext {
    teamcityDir = "$rootDir/servers/TeamCity-${TeamCityVersion}"
    teamcityDataDir = "$rootDir/data/" + (
            (TeamCityVersion ==~ /(\d+\.\d+).*/) ?
                    ((TeamCityVersion =~ /(\d+\.\d+).*/)[0][1])
                    : TeamCityVersion
    )
    teamcityJavaHome = System.properties['java.home']
}

teamcity {
    version = TeamCityVersion

    server {
        descriptor {
            name = project.name
            displayName = 'TeamCity GitHub Auth'
            version = project.version
            vendorName = 'JetBrains, s.r.o.'
            vendorUrl = 'https://www.jetbrains.com/'
            description = 'Allows authenticating using GitHub OAuth'
            useSeparateClassloader = true
        }

        environments {
            teamcityDev {
                version = TeamCityVersion
                homeDir = file(teamcityDir)
                dataDir = file(teamcityDataDir)
                javaHome = file(teamcityJavaHome)
                serverOptions '-Xdebug'
                serverOptions '-Xrunjdwp:transport=dt_socket,server=y,suspend=n,address=5500'

                serverOptions '-Dteamcity.development.mode=true'
                serverOptions '-Dteamcity.development.shadowCopyClasses=true'
            }

        }
    }
}