build.gradle

plugins {
    id 'org.springframework.boot' version '2.4.4'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
    id "info.solidsoft.pitest" version '1.5.1'
}

group = 'de.fh.kiel.advancedjava'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '15'
targetCompatibility = '15'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-neo4j'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation group: 'org.springdoc', name: 'springdoc-openapi-ui', version: '1.5.6'
    implementation group: 'commons-io', name: 'commons-io', version: '2.4'
    compileOnly 'org.projectlombok:lombok'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

test {
    useJUnitPlatform()
    // Always run tests, even when nothing changed.
    dependsOn 'cleanTest'
    // Show test results.
    testLogging {
        events "passed", "skipped", "failed"
    }
}
pitest {
    //adds dependency to org.pitest:pitest-junit5-plugin and sets "testPlugin" to "junit5"
    junit5PluginVersion = '0.12'
    /*
    The integration test give great coverage but if I run them with pitest the run is like 8 minutes.
     */
    excludedTestClasses = ['de.fh.kiel.advancedjava.pojomodel.integrationTests.**']
    /*
    These classes are not included because they are not covered for good reason, or their test are not included:
    tests not included ->  controller (are tested through the integration tests)
    just pojos -> dto, model
    utitlty application which is not part of the application -> CreateBase64Classes
    These would reduce the mution coverage because they are not covered but it makes no sense to cover them so
    it just makes the stats look worse. I a real world application I would do the same, instead of beginning to cover the pojos
     */
    excludedClasses = ['de.fh.kiel.advancedjava.pojomodel.controller.**',
                       'de.fh.kiel.advancedjava.pojomodel.dto.**',
                       'de.fh.kiel.advancedjava.pojomodel.model.**',
                       'de.fh.kiel.advancedjava.pojomodel.CreateBase64Classes'
    ]
}