publishing.gradle

apply plugin: "digital.wup.android-maven-publish"
apply plugin: "signing"

publishing {
    publications {
        basicJar(MavenPublication) {
            switch (POM_PACKAGING) {
                case "jar":
                    from components.java
                    break

                case "aar":
                    from components.android
                    break
            }

            artifact sourcesJar
            artifact javadocsJar

            pom {
                artifactId = POM_ARTIFACT_ID
                name = POM_NAME
                packaging = POM_PACKAGING
                description = POM_DESCRIPTION
                url = POM_URL

                scm {
                    connection = POM_SCM_CONNECTION
                    developerConnection = POM_SCM_DEV_CONNECTION
                    url = POM_SCM_URL
                }

                licenses {
                    license {
                        name = POM_LICENCE_NAME
                        url = POM_LICENCE_URL
                    }
                }

                developers {
                    developer {
                        id = "io7m"
                        name = "Mark Raynsford"
                        email = "code@io7m.com"
                        url = "https://www.io7m.com"
                    }
                    developer {
                        id = "winniequinn"
                        name = "Winnie Quinn"
                        url = "https://www.winniequinn.com/"
                    }
                    developer {
                        id = "gioneill"
                        name = "Greg O'Neill"
                        url = "https://github.com/gioneill"
                    }
                    developer {
                        id = "mattniehoff"
                        name = "Matt Niehoff"
                        url = "https://github.com/mattniehoff"
                    }
                    developer {
                        id = "MalcolmMcFly"
                        name = "Malcolm Woods"
                        url = "https://github.com/MalcolmMcFly"
                    }
                    developer {
                        id = "twaddington"
                        name = "Tristan Waddington"
                        url = "https://github.com/twaddington"
                    }
                }
            }
        }
    }

    repositories {
        if (useDirectoryPublish) {
            logger.info("using ${useDirectoryPublishPath} for publication")

            maven {
                name = "Directory"
                url = "file://${useDirectoryPublishPath}"
            }
        }

        if (version.endsWith("-SNAPSHOT")) {
            maven {
                url = "https://oss.sonatype.org/content/repositories/snapshots/"
                name = "SonatypeSnapshots"
                credentials(PasswordCredentials) {
                    username mavenCentralUsername
                    password mavenCentralPassword
                }
            }
        }
    }
}

if (!disableSigning) {
    apply plugin: "signing"

    signing {
        useGpgCmd()
        sign publishing.publications.basicJar
    }
}