build.gradle

/*
 * Copyright 2014 Netflix, Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
plugins {
  id 'io.spinnaker.project' version "$spinnakerGradleVersion" apply false
  id 'com.google.protobuf' version "0.8.12" apply false
}

allprojects {
  apply plugin: "io.spinnaker.project"
  repositories {mavenCentral()}
  tasks.withType(Copy).all {
    duplicatesStrategy 'exclude'
  }
}

subprojects {
  group = "io.spinnaker.halyard"
  apply plugin: 'java-library'
  apply plugin: 'groovy'

  test {
    useJUnitPlatform()
    testLogging {
      showStandardStreams = false
      exceptionFormat = 'full'
      afterSuite { desc, result ->
        if (!desc.parent) {
          println "Results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)"
          println "Report file: ${reports.html.entryPoint}"
        }
      }
    }
    minHeapSize = "512m"
    maxHeapSize = "512m"
  }

  if ([korkVersion, fiatVersion, clouddriverVersion, front50Version].any { it.endsWith("-SNAPSHOT") }) {
    logger.info("Enabling mavenLocal")
    repositories {
      mavenLocal()
       maven{
        url "NEXUS_URL"
           credentials {
                    username = "NEXUS_USERNAME"
                    password = "NEXUS_PASSWORD"
                         }
      }
    }
  }

  dependencies {

    constraints{
      api 'org.apache.ivy:ivy:2.5.2'
      implementation 'io.projectreactor.netty:reactor-netty-http:1.1.13'
    }
    implementation enforcedPlatform("io.spinnaker.kork:kork-bom:$korkVersion"){
      exclude group: 'org.apache.groovy', module: 'groovy'
    }
    implementation ("commons-fileupload:commons-fileupload:1.5")
    implementation("io.netty:netty-codec-http:5.0.0.Alpha2")
    implementation("org.apache.ivy:ivy:2.5.1")


    annotationProcessor platform("io.spinnaker.kork:kork-bom:$korkVersion")
    annotationProcessor "org.projectlombok:lombok"
    testAnnotationProcessor platform("io.spinnaker.kork:kork-bom:$korkVersion")
    testAnnotationProcessor "org.projectlombok:lombok"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine"
  }

}

defaultTasks ':halyard-web:run'

// Creates scripts for entry points
// Subproject must apply application plugin to be able to call this method.
def createScript(project, mainClass, name) {
  project.tasks.create(name: name, type: CreateStartScripts) {
    outputDir       = new File(project.buildDir, 'scripts')
    mainClassName   = mainClass
    applicationName = name
    classpath       = project.tasks[JavaPlugin.JAR_TASK_NAME].outputs.files + project.configurations.runtime
  }
  project.tasks[name].dependsOn(project.jar)

  project.applicationDistribution.with {
    into("bin") {
      from(project.tasks[name])
      fileMode = 0755
    }
  }
}