build.gradle

plugins {
    id "com.palantir.git-version" version "3.1.0"
}

def versionLabel(gitInfo) {
    def branch = gitInfo.branchName // all branches are snapshots, only tags get released
    def tag = gitInfo.lastTag
    // tag is returned as is. Branch may need cleanup
    return branch == null ? tag : 99 + "." + branch.replace("/","-") + "-SNAPSHOT"
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'checkstyle'
    apply plugin: 'jacoco'
    apply plugin: 'maven-publish'
    apply plugin: 'project-report'

    version = versionLabel(versionDetails())
    group = "mil.army.usace.hec"

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
    }

    test {
        finalizedBy jacocoTestReport
    }

    checkstyle {
        toolVersion '9.0.1'
    }

    jacoco {
        toolVersion = "0.8.7"
    }

    jacocoTestReport {
        dependsOn test
        reports {
            csv.required = true
            xml.required = true
            html.outputLocation = layout.buildDirectory.dir('jacoco')
        }
    }
}