build.gradle

//file:noinspection GroovyUnusedAssignment
plugins {
    id 'fabric-loom' version '1.0-SNAPSHOT'
    id 'eclipse'
    id 'maven-publish'
    //id 'io.github.juuxel.loom-quiltflower' version '1.+'
    id 'org.quiltmc.quilt-mappings-on-loom' version '4.2.+'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

version = project.mod_version
group = 'com.mrh0.createaddition'
archivesBaseName = "createaddition-fabric+${project.minecraft_version}"

println('Java: ' + System.getProperty('java.version') + ' JVM: ' + System.getProperty('java.vm.version') + '(' + System.getProperty('java.vendor') + ') Arch: ' + System.getProperty('os.arch'))

loom {
    sourceSets.main.resources { srcDir 'src/generated/resources' }
    accessWidenerPath = file("src/main/resources/ca.accesswidener")
}

repositories {
    maven {
        name 'Shedman maven'
        url 'https://maven.shedaniel.me/'
    }

    maven {
        name 'blamejared'
        url 'https://maven.blamejared.com'
    }
    maven { url = "https://api.modrinth.com/maven" }
    maven { url = "https://mvn.devos.one/releases/" }
    maven { url = "https://mvn.devos.one/snapshots/" }
    maven { url = "https://maven.tterrag.com/" }
    maven { url = "https://jitpack.io/" }
    maven {
        url 'https://www.cursemaven.com'
        content {
            includeGroup "curse.maven"
        }
    }
    maven {
        url = "https://maven.jamieswhiteshirt.com/libs-release"
        content {
            includeGroup("com.jamieswhiteshirt")
        }
    }
    maven { url = "https://maven.terraformersmc.com/" }
    maven { url = "https://maven.cafeteria.dev/releases" }
    maven {
        name = 'Ladysnake Mods'
        url = 'https://ladysnake.jfrog.io/artifactory/mods'
    }
    maven {
        name = "Progwml6 maven"
        url = "https://dvs1.progwml6.com/files/maven/"
    }
    maven {
        name = "ModMaven"
        url = "https://modmaven.dev"
    }
    maven {
        name = 'ParchmentMC'
        url = 'https://maven.parchmentmc.org'
    }
    maven { url "https://maven.bai.lol" }
}

dependencies {
    minecraft("com.mojang:minecraft:${project.minecraft_version}")

    mappings loom.layered {
        it.officialMojangMappings()
        it.parchment("org.parchmentmc.data:parchment-${project.minecraft_version}:${project.parchment_version}")
    }

    modImplementation("net.fabricmc:fabric-loader:${project.loader_version}")
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}+${project.minecraft_version}"

    modImplementation("me.shedaniel:RoughlyEnoughItems-api-fabric:${project.rei_version}")
    modImplementation("me.shedaniel:RoughlyEnoughItems-fabric:${project.rei_version}")

    modImplementation("mezz.jei:jei-${minecraft_version}-fabric:${jei_version}")

    modImplementation("dev.architectury:architectury-fabric:${project.architectury_version}")

    modImplementation("dev.onyxstudios.cardinal-components-api:cardinal-components-base:${cardinal_components_version}")

    modImplementation("com.simibubi.create:create-fabric-${project.minecraft_version}:" +
            "${project.create_version}+${project.minecraft_version}")

    modCompileOnly("curse.maven:cc-restitched-462672:3723736")

    modImplementation("appeng:appliedenergistics2-fabric:${project.ae2_version}")

    modImplementation("com.tterrag.registrate_fabric:Registrate:MC${project.minecraft_version}-${project.registrate_version}")
    modCompileOnly"mcp.mobius.waila:wthit-api:fabric-${wthit_version}"

    modApi("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_version}") {
        exclude(group: "net.fabricmc.fabric-api")
    }

    include modApi('teamreborn:energy:2.2.0') {
        exclude(group: "net.fabricmc.fabric-api")
    }
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

java {
    withSourcesJar()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact jar
        }
    }
    repositories {
        maven {
            url "file://${project.projectDir}/mcmodsrepo"
        }
    }
}