build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.netflix.nebula:gradle-extra-configurations-plugin:3.0.3'
    }
}

plugins {
//    id 'nebula.netflixoss' version '3.4.0'
    id 'nebula.maven-publish' version '4.9.1'
    id 'nebula.release' version '4.1.0'
    id 'nebula.dependency-lock' version '4.3.0'
    id 'nebula.info' version '3.2.1'
    id 'idea'
    id 'eclipse'
    id 'me.champeau.gradle.jmh' version '0.3.1'
    id 'net.saliman.cobertura' version '2.2.8'
}

ext {
    githubProjectName = rootProject.name
}

group = "com.netflix"

allprojects {
    repositories {
        jcenter()
    }

    apply plugin: 'net.saliman.cobertura'
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'eclipse'
    apply plugin: 'nebula.maven-publish'
    apply plugin: 'nebula.release'
    apply plugin: 'nebula.source-jar'
    apply plugin: 'nebula.dependency-lock'
    apply plugin: 'nebula.info'
    apply plugin: 'nebula.provided-base'
	apply plugin: 'nebula.compile-api'
	
    sourceCompatibility = 1.6
    targetCompatibility = 1.6



    group = "com.netflix.${githubProjectName}"

    eclipse {
        classpath {
            // include 'provided' dependencies on the classpath
            plusConfigurations += [configurations.provided]
            downloadSources = true
            downloadJavadoc = true
        }
    }

    idea {
        module {
            // include 'provided' dependencies on the classpath
            scopes.COMPILE.plus += [configurations.provided]
        }
    }

    publishing {
        repositories {
            maven {
                def releasesRepoUrl = "https://nexusng.tuenti.io/repository/maven-release-private/"
                def snapshotsRepoUrl = "https://nexusng.tuenti.io/repository/maven-snapshot-private/"
                url = version.toString().contains("SNAPSHOT") ? snapshotsRepoUrl : releasesRepoUrl
                credentials {
                    username = System.getenv "NEXUS_USER"
                    password = System.getenv "NEXUS_PASS"
                }
            }
        }
    }
}