mavencentral.gradle

task androidSourcesJar(type: Jar) {
    archiveClassifier.set('sources')
    from android.sourceSets.main.java.srcDirs
}

artifacts {
    archives androidSourcesJar
}

apply plugin: 'maven-publish'
apply plugin: 'signing'

ext {
    PUBLISH_GROUP_ID = 'com.telefonica'
    PUBLISH_ARTIFACT_ID = 'androidlogger'
    PUBLISH_VERSION = version

    PUBLISH_RELEASE_NAME = 'App Logger for Android'
    PUBLISH_NOOP_NAME = 'App Logger for Android NO-OP version'
    PUBLISH_DESCRIPTION = 'App Logger that allows app logs visualization, classification, filtering, sharing and recording from the application where it is included'
    PUBLISH_REPO_URL = 'https://github.com/Telefonica/android-logger'
}

publishing {
    publications {
        release(MavenPublication) {
            groupId PUBLISH_GROUP_ID
            artifactId PUBLISH_ARTIFACT_ID
            version PUBLISH_VERSION

            artifact("$buildDir/outputs/aar/${project.getName()}-enabled-release.aar")
            artifact androidSourcesJar

            pom {
                name = PUBLISH_RELEASE_NAME
                description = PUBLISH_DESCRIPTION
                url = PUBLISH_REPO_URL
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'android-team-telefonica'
                        name = 'Android Team'
                        email = 'cto-android@telefonica.com'
                    }
                }
                scm {
                    connection = 'scm:git:https://github.com/Telefonica/android-logger.git'
                    developerConnection = 'scm:git:ssh://https://github.com/Telefonica/android-logger.git'
                    url = 'https://github.com/Telefonica/android-logger/tree/main'
                }
                withXml {
                    def dependenciesNode = asNode().appendNode('dependencies')

                    project.configurations.getByName("enabledImplementation").allDependencies.each {
                        def dependencyNode = dependenciesNode.appendNode('dependency')
                        dependencyNode.appendNode('groupId', it.group)
                        dependencyNode.appendNode('artifactId', it.name)
                        dependencyNode.appendNode('version', it.version)
                    }
                }
            }
        }
        noop(MavenPublication) {
            groupId PUBLISH_GROUP_ID
            artifactId "$PUBLISH_ARTIFACT_ID-no-op"
            version PUBLISH_VERSION

            artifact("$buildDir/outputs/aar/${project.getName()}-noop-release.aar")
            artifact androidSourcesJar

            pom {
                name = PUBLISH_NOOP_NAME
                description = PUBLISH_DESCRIPTION
                url = PUBLISH_REPO_URL
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'android-team-telefonica'
                        name = 'Android Team'
                        email = 'cto-android@telefonica.com'
                    }
                }
                scm {
                    connection = 'scm:git:https://github.com/Telefonica/android-logger.git'
                    developerConnection = 'scm:git:ssh://https://github.com/Telefonica/android-logger.git'
                    url = 'https://github.com/Telefonica/android-logger/tree/main'
                }
                withXml {
                    def dependenciesNode = asNode().appendNode('dependencies')

                    project.configurations.getByName("noopImplementation").allDependencies.each {
                        def dependencyNode = dependenciesNode.appendNode('dependency')
                        dependencyNode.appendNode('groupId', it.group)
                        dependencyNode.appendNode('artifactId', it.name)
                        dependencyNode.appendNode('version', it.version)
                    }
                }
            }
        }
    }
}

signing {
    def signingKeyId = findProperty("signingKeyId")
    def signingKey = findProperty("signingKey")
    def signingPassword = findProperty("signingPassword")
    useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)
    sign publishing.publications
}

tasks.named('publishReleasePublicationToSonatypeRepository') { task ->
    task.dependsOn ':library:signNoopPublication'
}

tasks.named('publishNoopPublicationToSonatypeRepository') { task ->
    task.dependsOn ':library:signReleasePublication'
}