build.gradle

//file:noinspection GroovyAssignabilityCheck
plugins {
	id 'java'
	// Standard Artifact Publish
	id 'maven-publish'
	id 'signing'
	id 'io.codearte.nexus-staging' version '0.30.0'
    id "fabric-loom" version "1.7-SNAPSHOT" apply false
}
subprojects {
    apply plugin: 'java'
    apply plugin: 'maven-publish'
    apply plugin: 'signing'

    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
    java.toolchain.languageVersion = JavaLanguageVersion.of(21)

    group = project.maven_group
    version = "${project.mod_version}+${project.minecraft_version}"
    if (project.hasProperty('SNAPSHOT')) {
        version = "${version}-SNAPSHOT"
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = 'UTF-8'
        it.options.release.set(21)
    }

    javadoc.options.addStringOption('Xdoclint:none', '-quiet')

    nexusStaging {
        packageGroup = project.maven_group
    }

    jar {
        manifest {
            attributes([
                    'Specification-Title'     : archives_base_name,
                    'Specification-Vendor'    : 'The_Fireplace',
                    'Specification-Version'   : project.jar.archiveVersion,
                    'Implementation-Title'    : project.name,
                    'Implementation-Version'  : project.jar.archiveVersion,
                    'Implementation-Vendor'   : 'The_Fireplace',
                    'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                    'Timestampe'              : System.currentTimeMillis(),
                    'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
                    'Build-On-Minecraft'      : minecraft_version
            ])
        }
        from('LICENSE') {
            rename { "${it}_${archives_base_name}" }
        }
    }

    repositories {
        mavenCentral()

        maven {
            name = 'Sponge / Mixin'
            url = 'https://repo.spongepowered.org/repository/maven-public/'
        }

        /*maven {
            name = 'OSSRH Snapshots'
            url = 'https://oss.sonatype.org/content/repositories/snapshots/'
        }
        maven {
            name = 'OSSRH Snapshots Alt'
            url = 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
        }*/
    }

    // Disables Gradle's custom module metadata from being published to maven. The
	// metadata includes mapped dependencies which are not reasonably consumable by
	// other mod developers.
    tasks.withType(GenerateModuleMetadata).tap {
        configureEach {
            enabled = false
        }
    }
}