How to experience the latest fbc and vfbe (for Windows)

[chunmingwang]

I developed the following script for you to experience the latest fbc and vfbe (for Windows)

3 Steps to get the latest fbc and vfbe

update: 2023/03/04

1. Place fbc.bat and vfbe.bat in the same directory
2. Run fbc.bat first to download the latest fbc and reorganize the fbc directory locally
3. Then run vfbe.bat download the latest vfbe/mff and compile with fbc

fbc.bat

Copy the following batch script and rename it to fbc.bat

@echo off

rem Download fbc
rem Copyright (c) 2023 CM.Wang
rem Freeware. Use at your own risk.

setlocal ENABLEDELAYEDEXPANSION
set fbcpath=fbc
set curpath=!cd!
set unzip=C:\Program Files\7-Zip\7z.exe
set bits[1]=32
set bits[2]=64

set file[1]=freebasic_manual.chm
set msg[1]=fbc_manual
set url[1]=https://users.freebasic-portal.de/stw/builds/
set outpath[1]=

set file[2]=freebasic_additional_headers.zip
set msg[2]=fbc_base_headers
set url[2]=https://users.freebasic-portal.de/stw/builds/
set outpath[2]=

set file[3]=win32_mingw_additional_libs.zip
set msg[3]=fbc_base_win32_lib
set url[3]=https://users.freebasic-portal.de/stw/builds/
set outpath[3]=lib\win32

set file[4]=win64_mingw_additional_libs.zip
set msg[4]=fbc_base_win64_lib
set url[4]=https://users.freebasic-portal.de/stw/builds/
set outpath[4]=lib\win64

rem set file[5]=fbc_win32_mingw_0783_2022-06-24.zip
rem set file[5]=fbc_win32_mingw_0794_2023-01-22.zip
rem set file[5]=fbc_win32_mingw_0795_2023-02-11.zip
set file[5]=fbc_win32_mingw_0796_2023-03-04.zip
set msg[5]=fbc_win32
set url[5]=https://users.freebasic-portal.de/stw/builds/win32/
set outpath[5]=

rem set file[6]=fbc_win64_mingw_0795_2022-06-24.zip
rem set file[6]=fbc_win64_mingw_0805_2023-01-22.zip
rem set file[6]=fbc_win64_mingw_0806_2023-02-11.zip
set file[6]=fbc_win64_mingw_0807_2023-03-04.zip
set msg[6]=fbc_win64
set url[6]=https://users.freebasic-portal.de/stw/builds/win64/
set outpath[6]=

call :setesc
call :start
call :resetdownload
call :download
call :resetunzip
call :unzip
call :repath
call :end

cd !curpath!
setlocal DISABLEDELAYEDEXPANSION
pause
goto exit

:start
    if not exist !fbcpath! (
        md !fbcpath!
    )
    cd !fbcpath!

    echo.
    call :msg "Download fbc for win32/win64, file list:"
    echo.
    for /l %%n in (1,1,6) do (
        echo %%n. !url[%%n]!!file[%%n]!
    )
    echo.

    pause
    GOTO :EOF

:end
    call :msg "fbc for win32/win64 ready now" 92
    GOTO :EOF

:resetdownload
    call :msg "Delete exist download files [Y,N]?" 91
    choice /n /c "yn" /d "n" /t 5
    if errorlevel 2 GOTO :EOF
    for /l %%n in (1,1,6) do (
        if exist !file[%%n]! (
            echo Delete !file[%%n]!
            del !file[%%n]!
        )
    )
    GOTO :EOF

:download
    call :msg "Download fbc files"
    for /l %%n in (1,1,6) do (
        call :msg "!file[%%n]!" 94
        if not exist !file[%%n]! (
            echo %%n. Download !url[%%n]!!file[%%n]!
            curl -L -O !url[%%n]!!file[%%n]!
        ) else (
            echo Skipped download
        )
    )
    GOTO :EOF

:resetunzip
    call :msg "Delete previous unzip files"
    if exist bin rd bin /s /q>nul
    if exist inc rd inc /s /q>nul
    if exist lib rd lib /s /q>nul
    if exist *.exe del *.exe>nul
    if exist *.txt del *.txt>nul
    GOTO :EOF

:unzip
    call :msg "Unzip files"
    for /l %%n in (2,1,6) do (
        call :msg "%%n. Unzip !file[%%n]!" 94
        if exist "!unzip!" (
            if "!outpath[%%n]!" == "" (
                echo "!unzip!" x -aoa !file[%%n]!
                "!unzip!" x -aoa !file[%%n]!>nul
            ) else (
                echo "!unzip!" x -aoa !file[%%n]! -o!outpath[%%n]!\
                "!unzip!" x -aoa !file[%%n]! -o!outpath[%%n]!\>nul
            )
        ) else (
            if "!outpath[%%n]!" == "" (
                echo PowerShell Expand-Archive -LiteralPath "!file[%%n]!" -DestinationPath "." -Force
                PowerShell Expand-Archive -LiteralPath "!file[%%n]!" -DestinationPath "." -Force
            ) else (
                echo PowerShell Expand-Archive -LiteralPath "!file[%%n]!" -DestinationPath "!outpath[%%n]!" -Force
                PowerShell Expand-Archive -LiteralPath "!file[%%n]!" -DestinationPath "!outpath[%%n]!" -Force
            )
        )
    )
    GOTO :EOF

:repath
    call :msg "Reorganize fbc file's directory"

    for /l %%n in (1,1,2) do (
        ren fbc_win!bits[%%n]!_mingw\changelog.txt changelog!bits[%%n]!.txt
        ren fbc_win!bits[%%n]!_mingw\fbc.exe fbc!bits[%%n]!.exe
        ren fbc_win!bits[%%n]!_mingw\readme.txt readme!bits[%%n]!.txt

        xcopy fbc_win!bits[%%n]!_mingw /s /y>nul
        rd fbc_win!bits[%%n]!_mingw /s /q
    )
    GOTO :EOF

:msg
    set msg=%1
    set msg=%msg:"=%
    set clr=%2
    if "%clr%"=="" set clr=101;93
    echo.
    echo %ESC%[%clr%m%msg%%ESC%[0m
    GOTO :EOF

:setesc
    for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (
        set ESC=%%b
        GOTO :EOF
    )

:exit

vfbe.bat

Copy the following batch script and rename it to vfbe.bat

@echo off

rem VisualFBEditor/MyFbFramework download and complie 
rem Copyright (c) 2023 CM.Wang
rem Freeware. Use at your own risk.

setlocal ENABLEDELAYEDEXPANSION

set vfbepath=vfbe
set curpath=!cd!
set unzip=C:\Program Files\7-Zip\7z.exe
set bits[1]=32
set bits[2]=64

set file[1]=master.zip
set rename[1]=VisualFBEditor-master.zip
set url[1]=https://github.com/XusinboyBekchanov/VisualFBEditor/archive/refs/heads/
rem set url[1]=https://gitee.com/cm-wang/VisualFBEditor/repository/archive/
set repath[1]=VisualFBEditor-master
set cppath[1]=VisualFBEditor-master\src

set file[2]=master.zip
set rename[2]=MyFbFramework-master.zip
set url[2]=https://github.com/XusinboyBekchanov/MyFbFramework/archive/refs/heads/
rem set url[2]=https://gitee.com/cm-wang/MyFbFramework/repository/archive/
set repath[2]=MyFbFramework
set cppath[2]=VisualFBEditor-master\Controls\MyFbFramework\mff

set inifile[1]=VisualFBEditor32.ini
set inifile[2]=VisualFBEditor64.ini
set tempfile=temp.txt

set findline[1]=DefaultCompiler32=FreeBASIC-1.09.0-winlibs-gcc-9.3.0 x32
set replaceline[1]=DefaultCompiler32=fbc32

set findline[2]=DefaultCompiler64=FreeBASIC-1.09.0-winlibs-gcc-9.3.0 x64
set replaceline[2]=DefaultCompiler64=fbc64

set findline[3]=Path_0=fbc32
set replaceline[3]=Path_0=..\..\fbc\fbc32.exe

set findline[4]=Path_1=fbc64
set replaceline[4]=Path_1=..\..\fbc\fbc64.exe

call :setesc
call :start
call :resetdownload
call :download
call :resetunzip
call :unzip
call :repath
call :complie
call :replaceini
call :end

cd !curpath!
setlocal DISABLEDELAYEDEXPANSION
pause
goto exit

:start
    if not exist "!vfbepath!" (
        md "!vfbepath!"
    )
    cd "!vfbepath!"
    call :msg "Download VisualFBEditor file list:"
    for /l %%n in (1,1,2) do (
        echo %%n. !url[%%n]!!file[%%n]!
    )
    echo.
    pause
    GOTO :EOF

:end
    call :msg "VisualFBEditor ready now." 92
    GOTO :EOF

:resetdownload
    call :msg "Delete exist download files [Y,N]?" 91
    choice /n /c "yn" /d "n" /t 5
    if errorlevel 2 GOTO :EOF
    echo.
    for /l %%n in (1,1,2) do (
        if exist !rename[%%n]! (
            echo Delete !rename[%%n]!
            del !rename[%%n]!
        )
    )
    GOTO :EOF

:download
    call :msg "Download VisualFBEditor files"
    for /l %%n in (1,1,2) do (
        call :msg "!rename[%%n]!" 94
        if not exist "!rename[%%n]!" (
            curl -L -O !url[%%n]!!file[%%n]!
            if exist "!file[%%n]!" (
                echo %%n. Download !url[%%n]!!file[%%n]!
                ren "!file[%%n]!" "!rename[%%n]!"
            )
        ) else (
            echo Skipped download
        )
    )
    GOTO :EOF

:resetunzip
    call :msg "Delete previous unzip files"
    if exist MyFbFramework-master rd MyFbFramework-master /s /q
    if exist VisualFBEditor-master rd VisualFBEditor-master /s /q
    GOTO :EOF

:unzip
    call :msg "Unzip files"
    for /l %%n in (1,1,2) do (
        call :msg "%%n. Unzip !rename[%%n]!" 94
        if exist "!unzip!" (
            echo "!unzip!" x -aoa !rename[%%n]!
            "!unzip!" x -aoa !rename[%%n]!>nul
        ) else (
            echo PowerShell Expand-Archive -LiteralPath "!rename[%%n]!" -DestinationPath "." -Force
            PowerShell Expand-Archive -LiteralPath "!rename[%%n]!" -DestinationPath "." -Force
        )
    )
    GOTO :EOF

:repath
    call :msg "Reorganize VisualFBEditor file's directory"
    echo if exist MyFbFramework-master ren MyFbFramework-master !repath[2]!
    if exist MyFbFramework-master ren MyFbFramework-master !repath[2]!
    echo if exist !repath[2]! move MyFbFramework !repath[1]!\Controls
    if exist !repath[2]! move MyFbFramework !repath[1]!\Controls
    rem if exist "!curpath!\VisualFBEditor??.ini" copy "!curpath!\VisualFBEditor??.ini" "!curpath!\!vfbepath!\VisualFBEditor-master\Settings" /y
    GOTO :EOF

:complie
    call :msg "Complie VisualFBEditor"
    for /l %%n in (1,1,2) do (
        call :msg "Skip complie VisualFBEditor !bits[%%n]! [Y,N]?" 91
        choice /n /c "yn" /d "n" /t 5
        if errorlevel 2 (
            call :msg "Complie mff!bits[%%n]!" 94

            cd "!curpath!\!vfbepath!\!cppath[2]!"
            "!curpath!\fbc\fbc!bits[%%n]!.exe" -b "mff.bi" "mff.rc" -x "../mff!bits[%%n]!.dll" -dll -v

            call :msg "Complie VisualFBEditor!bits[%%n]!" 94

            cd "!curpath!\!vfbepath!\!cppath[1]!"
            "!curpath!\fbc\fbc!bits[%%n]!.exe" "VisualFBEditor.bas" "VisualFBEditor.rc" -i "../Controls/MyFbFramework" -x "../VisualFBEditor!bits[%%n]!.exe" -s gui -v
        )
    )
    GOTO :EOF

:replaceini
    call :msg "Set fbc for VisualFBEditor"
    cd "!curpath!\!vfbepath!\VisualFBEditor-master\Settings
    copy "!inifile[1]!" "Backup32.ini"/y>nul
    copy "!inifile[2]!" "Backup64.ini"/y>nul

    for /l %%n in (1,1,2) do (
        echo !inifile[%%n]!
        for /l %%m in (1,1,4) do (
            for /f "tokens=*" %%i in (!inifile[%%n]!) do (
               set line=%%i
               if "!line!"=="!findline[%%m]!" (
                   echo !replaceline[%%m]!>>!tempfile!
               ) else (
                   echo !line!>>!tempfile!
               )
            ) 
            del "!inifile[%%n]!"
            move "!tempfile!" "!inifile[%%n]!">nul
        )
    )
    goto :eof

:msg
    set msg=%1
    set msg=%msg:"=%
    set clr=%2
    if "%clr%"=="" set clr=101;93
    echo.
    echo %ESC%[%clr%m%msg%%ESC%[0m
    GOTO :EOF

:setesc
    for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (
        set ESC=%%b
        GOTO :EOF
    )
        
:exit

[XusinboyBekchanov]

Nice script files.

[chunmingwang]

Thank you for developing great vfbe.
I hope more people can easily experience this development tool.

Nice script files.