How To Change Price of Existing Inventory (PatchListingsItem)

[connexion2005]

Hello, I'm having a problem with updating the price of existing inventory. I'm receiving the following error:

"The provided payload is invalid."

The error is related to the "our_price" line. Can anyone help explain what I'm doing wrong with this code? This same code works fine for updating the quantities of our inventory but will not work for updating price.

Does anyone know how to get the serialized JSON I'm creating here converted to a string so I can review what I'm doing wrong on the our_price line?

Thanks!

Public Function patchListingPrice()
    Dim searchCriteria As New ParameterGetListingsItem()
    searchCriteria.sellerId = "A1NV87BN7I6TPH"
    searchCriteria.sku = "S911U1BA256GB"
    searchCriteria.marketplaceIds = New String() {MarketPlace.US.ID}
    searchCriteria.includedData = New ListingsIncludedData() {ListingsIncludedData.Summaries}
    Dim Listing = amazonConnection.ListingsItem.GetListingsItem(searchCriteria)

    Dim productType = listing.Summaries.First().ProductType

    Dim patch As New Dictionary(Of String, Object) From {
    {"marketplace_id", MarketPlace.US.ID},
    {"currency", "USD"},
    {"our_price", "[{""schedule"": [{""value_with_tax"": " & 509.99 & "}]}]"}
}

    Dim patches As FikaAmazonAPI.Parameter.ListingItem.PatchOperation() = {
    New FikaAmazonAPI.Parameter.ListingItem.PatchOperation With {
        .op = Op.replace,
        .path = "/attributes/purchasable_offer",
        .value = New List(Of Object) From {
            patch
        }
    }
}

    Dim listingPatch As New ParameterPatchListingItem() With {
    .sku = "S911U1BA256GB",
    .sellerId = "A1NV87BN7I6TPH",
    .marketplaceIds = New String() {MarketPlace.US.ID},
    .listingsItemPatchRequest = New ListingsItemPatchRequest() With {
        .productType = productType,
        .patches = patches
    }
}
    Dim response = amazonConnection.ListingsItem.PatchListingsItem(listingPatch)
    MessageBox.Show(response.ToString)
End Function

[connexion2005]

After some network monitoring by using Fiddler, I'm seeing my issue is related to the double quotes I'm attempting to use in the "our_price" object. They are turning into \ instead by the JSON serialization process. Can anyone assist with the appropriate way to write that particular section?

Thanks!

[connexion2005]

I was able to alleviate the issue using the below code and creating the nested objects rather than via the string method. Hopefully this helps someone out facing a similar issue. Thanks!

Public Function patchListingPrice()
        Dim searchCriteria As New ParameterGetListingsItem()
        searchCriteria.sellerId = "A1NV87BN7I6TPH"
        searchCriteria.sku = "S911U1BA256GB"
        searchCriteria.marketplaceIds = New String() {MarketPlace.US.ID}
        searchCriteria.includedData = New ListingsIncludedData() {ListingsIncludedData.Summaries}
        Dim Listing = amazonConnection.ListingsItem.GetListingsItem(searchCriteria)

        Dim productType = Listing.Summaries.First().ProductType

        'Create the new price object with the correct value
        Dim price As New ValuesWithTax()
        price.value_with_tax = 509.99

        'instantiate the OurPrice object
        Dim our_price_object = New OurPrice()

        'Instantiate a new empty list of price objects
        our_price_object.schedule = New List(Of ValuesWithTax)

        'Add the desired price object to the list of price objects
        our_price_object.schedule.Add(price)

        'Instantiate a List of Our Price objects, which will be the value of the "Object" in the dictionary
        Dim our_price_val = New List(Of OurPrice)

        'Add our created "OurPrice" object to the "list" of Our price objects
        our_price_val.Add(our_price_object)

        'Set it as the value of the "Object" in the dictionary string, Object
        Dim patch As New Dictionary(Of String, Object) From {
        {"marketplace_id", MarketPlace.US.ID},
        {"currency", "USD"},
        {"our_price", our_price_val}
        }

        Dim patches As FikaAmazonAPI.Parameter.ListingItem.PatchOperation() = {
        New FikaAmazonAPI.Parameter.ListingItem.PatchOperation With {
            .op = Op.replace,
            .path = "/attributes/purchasable_offer",
            .value = New List(Of Object) From {
                patch
            }
        }
    }

        Dim listingPatch As New ParameterPatchListingItem() With {
        .sku = "S911U1BA256GB",
        .sellerId = "A1NV87BN7I6TPH",
        .marketplaceIds = New String() {MarketPlace.US.ID},
        .listingsItemPatchRequest = New ListingsItemPatchRequest() With {
            .productType = productType,
            .patches = patches
        }
    }
        Dim response = amazonConnection.ListingsItem.PatchListingsItem(listingPatch)
        MessageBox.Show(response.ToString)
    End Function