build.gradle

plugins{
    id 'java'
    id 'com.github.johnrengelman.shadow' version '1.2.3'
    id 'maven'
    id 'jacoco'
    id 'com.github.kt3k.coveralls' version '2.6.3'
}

jacocoTestReport {
    reports {
        xml.enabled = true // coveralls plugin depends on xml format report
        html.enabled = true
        html.destination "${buildDir}/jacocoHtml"
    }
}

allprojects {
    repositories {
        maven { url "https://jitpack.io" }
    }
}

jar {
    baseName = 'eiffel-remrem-semantics'
    // If this version is updated please update it in Event.java 
    // com.ericsson.eiffel.remrem.semantics.events
    version =  '0.1.8'
    manifest {
        attributes('remremVersionKey': 'semanticsVersion')
        attributes('semanticsVersion': version)
        attributes('isEndpointVersion': 'true')
    }
    from { configurations.runtime.collect { it.isDirectory() ? it : zipTree(it) } }
}

shadowJar {
    baseName = 'eiffel-remrem-semantics'
    version =  '0.1.8'
    classifier = ''
}

apply plugin: 'eclipse'

task wrapper(type: Wrapper) {
    gradleVersion = '3.1'
    distributionUrl = "https://services.gradle.org/distributions/gradle-$gradleVersion-all.zip"
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    maven { url "https://jitpack.io" }
    maven {
        url "https://eiffel.lmera.ericsson.se/nexus/service/local/repositories/releases/content"
    }
    mavenCentral()
    jcenter()
    flatDir {
        dirs 'libs'
    }
}

install.dependsOn shadowJar

dependencies {
    compile 'com.github.Ericsson:eiffel-remrem-shared:0.1.5'    
    compile('com.github.fge:json-schema-validator:2.2.6')
    {
    // we need to exclude jackson-databind here and add a
    // new version afterwards. The reason is the incompatibility
    // with applications based on newer versions of Spring framework
    // and using semantics as a library 
        exclude module: 'jackson-databind'
    }
    compile 'com.fasterxml.jackson.core:jackson-databind:2.8.3'
    compile 'org.mockito:mockito-core:1.10.19'
    compile 'javax.inject:javax.inject:1'
    compile 'org.slf4j:slf4j-api:1.7.18'
    compile group: 'com.google.code.gson', name: 'gson', version: '1.7.2'
    testCompile 'junit:junit:4.12'
}