alternating screens on display with different sensor readings

[greenlandpaddle]

Dear all, I guess there is a much simpler solution for a rule for alternating screens containing different sensor readings (in my case on SH1106 display). Do you have an idea? No need to mention that this is my first contact with rules. Thank you in advance.

rule1 on tele-DS18B20-434E80#Temperature do backlog DisplayText [zs1l1c1]Temperatur aussen (Grad Celsius) [s2l2c1]%value%; ruletimer1 4 endon 
	  ON rules#timer=1 DO backlog rule1 0; rule2 1; rule3 0 ENDON

rule2 on tele-BMP180#Temperature do backlog DisplayText [zs1l1c1]Temperatur innen (Grad Celsius) [s2l2c1]%value%; ruletimer1 4 endon 
	  ON rules#timer=1 DO backlog rule1 0; rule2 0; rule3 1 ENDON

rule3 on tele-BMP180#Pressure do backlog DisplayText [zs1l1c1]Luftdruck (mBar) [s2l2c1]%value%; ruletimer1 4 endon 
	  ON rules#timer=1 DO backlog rule1 1; rule2 0; rule3 0 ENDON

[sfromis]

What I'd suggest is not "simpler" but instead working better (if my assumptions about your intentions are right). The rules you post there have two issues.

First, the tele- triggers will only fire at the telemetry period (default 300 seconds, minimum 10 seconds), and I'm guessing (?) you'd want it every 4 seconds or something like that. While you could use triggers without the tele- prefix for much faster reactions, it would still not be a stable update rhythm at such a fixed short interval.

Second, updating rule set status very often contributes to flash wear, to the detriment of flash lifetime, which could be a factor if aiming for a reasonably quick update cycle. While it is possible to turn off saving via the SaveData command, that is easy to forget if you make other changes, and you still may have the issue of a stable update cycle timing.

One way could be to change the rules to pick up sensor values to instead save last value in a variable for each, like on tele-BMP180#Temperature do var2 %value% endon without displaying.

Then you could have your cycle of 4 seconds (or what you want) using RuleTimer the same way, but have it update a counter variable like var9=(var9+1)%3 producing values of 0,1,2

Updating each in the cycle could then be rules like:
on var9#state==1 do DisplayText [zs1l1c1]Temperatur innen (Grad Celsius) [s2l2c1]%var2% endon

However, if your device is based on the recommended ESP32, you have much better options for managing the updating via the Berry language, instead of using rules.

[greenlandpaddle]

I tried to stick with rules for now. Defining the three variables works fine, after that nothing. And I guess the *** marked line should be the (first) problem. That seems the wrong path to define a ruletimer. Any suggestions? Looks like I did not got the concept for now.

rule1 
on tele-DS18B20-434E80#Temperature do var1 %value% endon 
on tele-BMP180#Temperature do var2 %value% endon 
on tele-BMP180#Pressure do var3 %value% endon

*****on event do ruletimer1 2 endon

on rules#timer=1 do var9=(var9+1)%3 endon
on var9#state==1 do DisplayText [zs2l1c1]Temp >>[s3l2c2]%var1% endon
on var9#state==2 do DisplayText [zs2l1c1]Temp <<[s3l2c2]%var2% endon
on var9#state==3 do DisplayText [zs2l1c1]Luftdruck[s3l2c2]%var3% endon

[sfromis]

Right, nothing will indeed work, until you make sure to start and restart the RuleTimer, which means restarting it every time it popped (in the rule setting var9), and making sure to start if after boot, like from a rule triggered by System#boot.

But still, if you are using ESP32, I really cannot recommend sticking with rules, as there are many special quirks needed to get things working there.

[greenlandpaddle]

Perfect, now I got it. Many thanks for your help! Next time I will dive into Berry-language.
Here is the working rule for alternating screens showing different sensor values on one display. As a reminder: Restart required for test.

rule1 
on system#boot do backlog ruletimer1 3; var9 0 endon

on tele-DS18B20-434E80#Temperature do var1 %value% endon 
on tele-BMP180#Temperature do var2 %value% endon 
on tele-BMP180#Pressure do var3 %value% endon

on rules#timer=1 do backlog var9=(var9+1)%3; ruletimer1 3 endon

on var9#state==0 do DisplayText [zs2l1c1]Temp >>[s3l2c2]%var1% endon
on var9#state==1 do DisplayText [zs2l1c1]Temp <<[s3l2c2]%var2% endon
on var9#state==2 do DisplayText [zs2l1c1]Luftdruck[s3l2c1]%var3% endon