-
Notifications
You must be signed in to change notification settings - Fork 4
/
remote.ahk
412 lines (336 loc) · 10.9 KB
/
remote.ahk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
; Zoom for StarBreak (injected script)
; by atomizer
#NoEnv
#Persistent
#Warn
#InstallKeybdHook
#MaxThreads, 1
SetBatchLines -1
ListLines Off
if (!A_IsDll) {
ExitApp
}
OnExit, Cleanup
Menu, tray, NoStandard
Menu, tray, Icon, mvmmoclient.exe, -1
Menu, tray, Tip, zoom
; --------------------------------------------------------------------------
; constants
ini := "zoom.ini"
; size of the offscreen framebuffer
BUFFERWIDTH := 4096
BUFFERHEIGHT := 4096
SysGet, MonitorPrimary, MonitorPrimary
IniRead, MonitorID, %ini%, window, monitor, %MonitorPrimary%
IniWrite, %MonitorID%, %ini%, window, monitor
SysGet, bounds, MonitorWorkArea, %MonitorID%
; window size
wLeft := boundsLeft
wTop := boundsTop
IniRead, wWidth, %ini%, window, width
IniRead, wHeight, %ini%, window, height
if (wWidth = "ERROR" || wHeight = "ERROR") {
wWidth := boundsRight - boundsLeft
wHeight := boundsBottom - boundsTop
}
IniWrite, %wWidth%, %ini%, window, width
IniWrite, %wHeight%, %ini%, window, height
; keys
IniRead, keyZoomIn, %ini%, keys, zoomin, NumpadAdd
IniRead, keyZoomOut, %ini%, keys, zoomout, NumpadSub
IniRead, keyNative, %ini%, keys, native, Numpad0
IniWrite, %keyZoomIn%, %ini%, keys, zoomin
IniWrite, %keyZoomOut%, %ini%, keys, zoomout
IniWrite, %keyNative%, %ini%, keys, native
; horisontal resolution difference per step
zstep := 640
; bounds for zoom, in zsteps
minZoom := 2
maxZoom := 6
; key delay
keyDelay := 300
; hp
IniRead, hpBar, %ini%, hp, bar, 1
IniRead, hpSize, %ini%, hp, size, 28
IniWrite, %hpBar%, %ini%, hp, bar
IniWrite, %hpSize%, %ini%, hp, size
; --------------------------------------------------------------------------
; globals
; first run flag
needsetup := true
; represents current screen width in zsteps
zoom := wWidth / zstep
aspectRatio := wHeight / wWidth
; current game resolution
cWidth := wWidth
cHeight := wHeight
framebuffer := 0
renderbuffer := 0
lastKeyTime := 0
; --------------------------------------------------------------------------
; GL constants
GL_FRAMEBUFFER := 0x8D40
GL_RENDERBUFFER := 0x8D41
GL_READ_FRAMEBUFFER := 0x8CA8
GL_DRAW_FRAMEBUFFER := 0x8CA9
GL_COLOR_ATTACHMENT0 := 0x8CE0
GL_FRAMEBUFFER_COMPLETE := 0x8CD5
GL_BACK := 0x0405
GL_TEXTURE_2D := 0x0DE1
GL_TEXTURE_WRAP_S := 0x2802
GL_TEXTURE_WRAP_T := 0x2803
GL_TEXTURE_MAG_FILTER := 0x2800
GL_TEXTURE_MIN_FILTER := 0x2801
GL_NEAREST := 0x2600
GL_LINEAR := 0x2601
GL_REPEAT := 0x2901
GL_CLAMP := 0x2900
GL_RGBA8 := 0x8058
GL_BGRA := 0x80E1
GL_UNSIGNED_BYTE := 0x1401
GL_COLOR_BUFFER_BIT := 0x4000
GL_TRIANGLES := 0x0004
GL_QUADS := 0x0007
GL_POLYGON := 0x0009
GL_MODELVIEW := 0x1700
GL_PROJECTION := 0x1701
GL_TEXTURE := 0x1702
GL_BLEND := 0x0BE2
; --------------------------------------------------------------------------
; init
PID := DllCall("GetCurrentProcessId")
WinWait, ahk_pid %PID%
sleep 3000
getGLProc := DynaCall("SDL2\SDL_GL_GetProcAddress", "i=a")
setWinPos := DynaCall("SetWindowPos", "t==ttiiiii")
TTFOpenFont := DynaCall("SDL2_ttf\TTF_OpenFont", "t==ai")
TTFSetFontOutline := DynaCall("SDL2_ttf\TTF_SetFontOutline", "ti")
hpfont := TTFOpenFont["client\data\font\HemiHeadBold.ttf", hpSize]
hpoutlinefont := TTFOpenFont["client\data\font\HemiHeadBold.ttf", hpSize]
TTFSetFontOutline[hpoutlinefont, 2]
; --------------------------------------------------------------------------
; hooks
hMinHook := DllCall("LoadLibrary", "Str", "MinHook.dll", "Ptr")
if (ErrorLevel) {
MsgBox % "Failed to load MinHook.dll: " . ErrorLevel
return
}
DllCall("MinHook\MH_Initialize", "Int")
origPtr := 0
; SDL_GL_SwapWindow
hookPtr := RegisterCallback("SwapWindowHook", "", 1)
DllCall("MinHook\MH_CreateHookApi", "Str", "SDL2", "AStr", "SDL_GL_SwapWindow", "Ptr", hookPtr, "PtrP", origPtr, "Int")
origSwapWindow := DynaCall(origPtr, "t")
; SDL_GetWindowSize
hookPtr := RegisterCallback("GetWindowSizeHook", "", 3)
DllCall("MinHook\MH_CreateHookApi", "Str", "SDL2", "AStr", "SDL_GetWindowSize", "Ptr", hookPtr, "PtrP", origPtr, "Int")
origGetWindowSize := DynaCall(origPtr, "ttt")
; SDL_GL_GetDrawableSize
hookPtr := RegisterCallback("GLGetDrawableSizeHook", "C", 3)
DllCall("MinHook\MH_CreateHookApi", "Str", "SDL2", "AStr", "SDL_GL_GetDrawableSize", "Ptr", hookPtr, "PtrP", origPtr, "Int")
origGLGetDrawableSize := DynaCall(origPtr, "ttt")
; TTF_RenderUTF8_Blended
hookPtr := RegisterCallback("TTFRenderHook", "C", 3)
DllCall("MinHook\MH_CreateHookApi", "Str", "SDL2_ttf", "AStr", "TTF_RenderUTF8_Blended", "Ptr", hookPtr, "PtrP", origPtr, "Int")
origTTFRender := DynaCall(origPtr, "i==tti")
; enable everything
DllCall("MinHook\MH_EnableHook", "Ptr", 0, "Int")
; --------------------------------------------------------------------------
; start the party
update()
return
; END OF AUTOEXEC
; --------------------------------------------------------------------------
; hooked functions
GetWindowSizeHook(window, width, height) {
critical
global origGetWindowSize, cWidth, cHeight
; return the resolution that we want the game to render at
NumPut(cWidth, width + 0, "Int")
NumPut(cHeight, height + 0, "Int")
}
GLGetDrawableSizeHook(window, width, height) {
critical
global origGLGetDrawableSize, cWidth, cHeight
; these will be used by the game in a glViewport() call
NumPut(cWidth, width + 0, "Int")
NumPut(cHeight, height + 0, "Int")
}
SwapWindowHook(window) {
critical
global GL_FRAMEBUFFER, GL_RENDERBUFFER, GL_FRAMEBUFFER_COMPLETE
global GL_DRAW_FRAMEBUFFER, GL_READ_FRAMEBUFFER, GL_COLOR_ATTACHMENT0, GL_BACK, GL_COLOR_BUFFER_BIT, GL_LINEAR, GL_NEAREST, GL_RGBA8
global BUFFERWIDTH, BUFFERHEIGHT
global glGenFramebuffers, glBindFramebuffer, glBindRenderbuffer, glRenderbufferStorage, glGenRenderbuffers
global glFramebufferRenderbuffer, glCheckFramebufferStatus, glBlitFramebuffer, glGetError
global origSwapWindow, needsetup, framebuffer, renderbuffer
global wWidth, wHeight, cWidth, cHeight, hpBar
if (needsetup) {
InitGLFunctions()
; framebuffer
glGenFramebuffers[1, &framebuffer]
checkGLError("glGenFramebuffers")
framebuffer := NumGet(&framebuffer)
glBindFramebuffer[GL_FRAMEBUFFER, framebuffer]
checkGLError("glBindFramebuffer")
; renderbuffer
glGenRenderbuffers[1, &renderbuffer]
checkGLError("glGenRenderbuffers")
renderbuffer := NumGet(&renderbuffer)
glBindRenderbuffer[GL_RENDERBUFFER, renderbuffer]
checkGLError("glBindRenderbuffer")
glRenderbufferStorage[GL_RENDERBUFFER, GL_RGBA8, BUFFERWIDTH, BUFFERHEIGHT]
checkGLError("glRenderbufferStorage")
; attach one to the other
glFramebufferRenderbuffer[GL_FRAMEBUFFER, GL_COLOR_ATTACHMENT0, GL_RENDERBUFFER, renderbuffer]
checkGLError("glFramebufferRenderbuffer")
; check for gremlins
status := glCheckFramebufferStatus[GL_FRAMEBUFFER]
if (status != GL_FRAMEBUFFER_COMPLETE) {
MsgBox, 16, , Framebuffer is not complete.`nStatus code: %status%
ExitApp
}
needsetup := false
}
; copy what was drawn on the framebuffer to the screen
glBindFramebuffer[GL_DRAW_FRAMEBUFFER, 0]
glBlitFramebuffer[0, 0, cWidth, cHeight, 0, 0, wWidth, wHeight, GL_COLOR_BUFFER_BIT, GL_LINEAR]
checkGLError("glBlitFramebuffer")
; hp bar
if (hpBar) {
glBlitFramebuffer[235, cHeight - 55, 236, cHeight - 56, 0, wHeight - 7, wWidth, wHeight - 5, GL_COLOR_BUFFER_BIT, GL_NEAREST]
glBlitFramebuffer[109, cHeight - 41, 217, cHeight - 40, 0, wHeight - 5, wWidth, wHeight, GL_COLOR_BUFFER_BIT, GL_LINEAR]
}
; don't forget to call the original function
glBindFramebuffer[GL_FRAMEBUFFER, 0]
origSwapWindow[window]
; redirect drawing to our framebuffer
glBindFramebuffer[GL_FRAMEBUFFER, framebuffer]
; we are already running every frame, might as well do hotkeys by hand
checkKeys()
}
TTFRenderHook(font, text, color) {
critical
global origTTFRender
global hpfont, hpoutlinefont
str := StrGet(text, , "UTF-8")
if (RegExMatch(str, "^\d+/(\d+)$", match) && match1 >= 50) {
if (color = 0xff000000) {
font := hpoutlinefont
} else {
font := hpfont
}
}
ret := origTTFRender[font, text, color]
return ret
}
; --------------------------------------------------------------------------
; hotkey functions
checkKeys() {
global lastKeyTime, keyDelay, keyNative, keyZoomIn, keyZoomOut
if (A_TickCount - lastKeyTime < keyDelay) {
return
}
if (GetKeyState(keyNative, "P")) {
lastKeyTime := A_TickCount
native()
return
}
if (GetKeyState(keyZoomIn, "P")) {
lastKeyTime := A_TickCount
zoomin()
return
}
if (GetKeyState(keyZoomOut, "P")) {
lastKeyTime := A_TickCount
zoomout()
return
}
}
zoomout() {
global zoom, maxZoom
pz := zoom
zoom := Round(zoom + 1)
if (zoom > maxZoom) {
zoom := maxZoom
}
if (pz = zoom)
return
update()
}
zoomin() {
global zoom, minZoom
pz := zoom
zoom := Round(zoom - 1)
if (zoom < minZoom) {
zoom := minZoom
}
if (pz = zoom)
return
update()
}
native() {
global wWidth, zoom, zstep
pz := zoom
zoom := wWidth / zstep
if (pz = zoom)
return
update()
}
update() {
global zoom, zstep, aspectRatio, cWidth, cHeight, window, PID
WinGet, window, ID, ahk_pid %PID%
if (!window) {
MsgBox, 16, , Unexpected condition: the game window no longer exists.
ExitApp
}
cWidth := Round(zoom * zstep)
cHeight := Round(cWidth * aspectRatio)
WinSet, Style, -0xC40000, ahk_id %window%
pingWindow()
str := cWidth . " x " . cHeight
Menu, tray, tip, %str%
}
; send resize event to trigger the hooks
pingWindow() {
global setWinPos, window, wLeft, wTop, wWidth, wHeight
setWinPos[window, 0, wLeft, wTop, wWidth, wHeight + 1, 0]
setWinPos[window, 0, wLeft, wTop, wWidth, wHeight, 0]
}
log(str) {
logFile := FileOpen("zoomlog.txt", "a")
logFile.WriteLine(A_Now . " " . str)
logFile.Close()
}
InitGLFunctions() {
global
glGenRenderbuffers := DynaCall(getGLProc["glGenRenderbuffers"], "it")
glDeleteRenderbuffers := DynaCall(getGLProc["glDeleteRenderbuffers"], "it")
glRenderbufferStorage := DynaCall(getGLProc["glRenderbufferStorage"], "iiii")
glBindRenderbuffer := DynaCall(getGLProc["glBindRenderbuffer"], "ii")
glBlitFramebuffer := DynaCall(getGLProc["glBlitFramebuffer"], "iiiiiiiiii")
glCheckFramebufferStatus := DynaCall(getGLProc["glCheckFramebufferStatus"], "i==i")
glBindFramebuffer := DynaCall(getGLProc["glBindFramebuffer"], "ii")
glGenFramebuffers := DynaCall(getGLProc["glGenFramebuffers"], "it")
glDeleteFramebuffers := DynaCall(getGLProc["glDeleteFramebuffers"], "it")
glFramebufferRenderbuffer := DynaCall(getGLProc["glFramebufferRenderbuffer"], "iiii")
glGetError := DynaCall(getGLProc["glGetError"], "i==")
}
checkGLError(lastfunc) {
global glGetError
err := glGetError[]
if (err = 0)
return
MsgBox, 16, , GL error!`n`nFunction: %lastfunc%`nError code: %err%
ExitApp
}
Cleanup:
; probably fogetting something
DllCall("MinHook\MH_Uninitialize", "Int")
DllCall("FreeLibrary", "Ptr", hMinHook)
if (!needsetup) {
glBindFramebuffer[GL_FRAMEBUFFER, 0]
glDeleteRenderbuffers[1, &renderbuffer]
glDeleteFramebuffers[1, &framebuffer]
}
ExitApp