default.nix

{ pkgs, config, ... }:
let
  cursor-alias = pkgs.writeShellScriptBin "code" ''
    exec cursor "$@"
  '';
  cursor-wrapper = pkgs.writeShellScriptBin "cursor" ''
    exec ${pkgs.sway-open}/bin/sway-open \
      --app_id code-url-handler \
      --new-window-argument="--new-window" \
      -- \
      ${pkgs.code-cursor}/bin/cursor \
      "$@"
  '';
  chromium-wrapper = pkgs.writeShellScriptBin "chromium" ''
    exec ${pkgs.sway-open}/bin/sway-open \
      --app_id chromium-browser \
      --new-window-argument="--new-window" \
      -- \
      ${config.programs.chromium.package}/bin/chromium \
      "$@"
  '';
in
{
  imports = [
    ./modules/blueberry.nix
    ./modules/lxqt-policykit-agent.nix
    ./modules/xssproxy.nix
    ./modules/nushell.nix
  ];
  config = {
    home.packages = with pkgs; [
      # Development Tools
      nixfmt-rfc-style
      gdb
      nodejs
      clang
      jdk
      maven
      deno
      devenv
      watchman

      # Version Control
      hub
      gh
      git-cola
      git-absorb
      git-revise
      git-worktree-shell
      tig

      # Text Processing & Search
      ripgrep
      fd
      sd
      xsv
      q-text-as-data
      delta
      ast-grep

      # System Tools
      socat
      file
      qemu
      darkhttpd
      lsof
      bottom
      procs
      dua
      nix-output-monitor

      # Network Tools
      nmap
      httpie
      insomnia
      docker-compose

      # File Management
      xfce.thunar
      xfce.xfconf
      xfce.tumbler
      xfce.exo
      file-roller
      meld

      # Media & Graphics
      mplayer
      imagemagick
      vlc
      gimp
      feh
      ffmpeg-full
      ffmpegthumbnailer
      audacity
      inkscape
      peek

      # Desktop Environment
      pavucontrol
      volumeicon
      lxappearance
      i3status
      networkmanagerapplet
      dconf

      # Security & Privacy
      bitwarden
      bitwarden-cli
      keepassxc
      gnupg

      # Communication & Collaboration
      slack
      zoom-us
      thunderbird

      # Text Editors & IDEs
      helix
      (lib.hiPrio cursor-wrapper)
      (lib.hiPrio chromium-wrapper)
      cursor-alias

      # Productivity
      pomodoro
      libreoffice
      speedcrunch
      chatgpt-cli

      # CLI Utilities
      entr
      xclip
      jq
      graphviz
      screen
      yq-go
      watchexec
      difftastic
      du-dust
      fx
      cachix
      ijq
      zoxide
      nodePackages.zx
      xdg-utils
      nixpkgs-review

      # Fonts
      liberation_ttf
      ttf_bitstream_vera

      # Misc
      coin
      spotify
      mono
      patchelf
      tiled
      home-manager
      xsel
    ];

    dconf = {
      enable = true;
      settings = {
        "org/gnome/desktop/sound" = {
          event-sounds = false;
          input-feedback-sounds = false;
        };
      };
    };

    programs.chromium.enable = true;

    programs.lazygit = {
      enable = true;
      settings = {
        git.overrideGpg = true;
        customCommands = [
          {
            key = "N";
            context = "global";
            command = "git fetch origin HEAD && git checkout FETCH_HEAD";
          }
        ];
      };
    };

    programs.terminator = {
      enable = true;
      config = {
        global_config = {
          inactive_color_offset = "1.0";
        };
        keybindings = {
          go_next = "";
          new_window = "<Primary><Shift>n";
        };
        profiles.default = {
          background_color = "#002b36";
          cursor_color = "#aaaaaa";
          font = "SauceCodePro Nerd Font 11";
          use_system_font = false;
          foreground_color = "#839496";
          show_titlebar = false;
          scrollback_lines = 10000;
          palette = "#073642:#dc322f:#859900:#b58900:#268bd2:#d33682:#2aa198:#eee8d5:#002b36:#cb4b16:#586e75:#657b83:#839496:#6c71c4:#93a1a1:#fdf6e3";
        };
      };
    };

    fonts.fontconfig.enable = true;
    gtk = {
      enable = true;
      font = {
        name = "Noto Sans 10";
        package = pkgs.noto-fonts;
      };
      iconTheme = {
        name = "Adwaita";
        package = pkgs.adwaita-icon-theme;
      };
      theme = {
        name = "Adwaita-dark";
        package = pkgs.gnome-themes-extra;
      };
      gtk2.extraConfig = ''
        gtk-error-bell = 0
      '';

      gtk3.extraConfig = {
        gtk-error-bell = 0;
      };
    };
    programs.ssh = {
      enable = true;
      forwardAgent = false;
      serverAliveInterval = 180;
      matchBlocks = {
        "beheer1.ioservice.net beheer1.stpst.nl beheer2.ioservice.net beheer2.stpst.nl" = {
          user = "bob.vanderlinden";
          forwardAgent = false;
          identityFile = "~/.ssh/nedap_rsa";
        };

        "nl12* nl14* nl22* nl24* vm* nvs* nas* *.healthcare.nedap.local *.consul" = {
          user = "bob.vanderlinden";
          forwardAgent = false;
          identityFile = "~/.ssh/nedap_rsa";
          extraOptions = {
            VerifyHostKeyDNS = "no";
            ProxyJump = "beheer1.ioservice.net";
          };
        };

        "127.0.0.1" = {
          user = "bob.vanderlinden";
          forwardAgent = false;
          identityFile = "~/.ssh/nedap_rsa";
          extraOptions.VerifyHostKeyDNS = "no";
        };

        "github.com" = {
          user = "git";
          identityFile = "~/.ssh/github_ed25519";
        };
      };
    };
    programs.fzf.enable = true;
    programs.bat.enable = true;
    programs.fish = {
      enable = true;
      interactiveShellInit = ''
        set fish_greeting
      '';
    };

    programs.nushell = {
      enable = true;
      settingss.show_banner = false;
      extraConfig = ''
        source ${
          pkgs.fetchurl {
            url = "https://raw.githubusercontent.com/nushell/nu_scripts/e3b02b38eeece7c4ab8c20198cd36c6b12d5c3e4/background_task/job.nu";
            hash = "sha256-L+SrTstXey9WhT4gHD4Wu++HEIMsh1LaNjWd2ouRLjI=";
          }
        }
      '';
      shellAliases = config.home.shellAliases;
    };
    services.pueue = {
      enable = true;
      settings.shared.use_unix_socket = true;
    };

    programs.starship = {
      enable = true;
      settings = {
        character = {
          success_symbol = "[\\$](bold blue)";
          error_symbol = "[\\$](bold red)";
        };
      };
    };

    programs.atuin = {
      enable = true;
      flags = [ "--disable-up-arrow" ];
      settings = {
        auto_sync = false;
        update_check = false;
        style = "compact";
      };
    };

    programs.zoxide.enable = true;

    qt = {
      enable = true;
      platformTheme.name = "adwaita";
      style = {
        name = "adwaita-dark";
        package = pkgs.adwaita-qt;
      };
    };

    services.gpg-agent.enable = true;

    services.network-manager-applet.enable = true;
    services.blueberry.enable = true;
    services.mpris-proxy.enable = true;
    services.flameshot = {
      enable = true;
      package = pkgs.flameshot.overrideAttrs (oldAttrs: {
        buildInputs = oldAttrs.buildInputs ++ [ pkgs.libsForQt5.kguiaddons ];
        cmakeFlags = [ "-DUSE_WAYLAND_CLIPBOARD=true" ];
      });
    };
    services.darkman = {
      enable = true;
      settings = {
        usegeoclue = true;
      };
    };

    services.gammastep = {
      enable = true;
      provider = "geoclue2";
      temperature.day = 5500;
      temperature.night = 3700;
      tray = true;
    };

    services.xsettingsd.enable = true;
    services.xsettingsd.settings = {
      "Net/ThemeName" = "Adwaita-dark";
      "Xft/Antialias" = true;
      "Xft/Hinting" = true;
      "Xft/RGBA" = "rgb";
    };
    programs.kitty = {
      themeFile = "adwaita_dark";
      keybindings."ctrl+shift+n" = "new_os_window_with_cwd";
    };

    services.xssproxy.enable = false;
    services.lxqt-policykit-agent.enable = true;

    services.pasystray.enable = true;

    xdg.enable = true;
    # news.display = "silent";

    home.pointerCursor = {
      x11.enable = true;
      name = "Vanilla-DMZ";
      package = pkgs.vanilla-dmz;
      size = 128;
    };

    home.shellAliases = {
      g = "git";
    };

    programs.git = {
      enable = true;
      userName = "Bob van der Linden";
      userEmail = "bobvanderlinden@gmail.com";
      delta.enable = true;
      aliases = {
        unstage = "reset HEAD --";
        sw = "switch";
        co = "checkout";
        c = "commit";
        b = "branch";
        p = "push";
        pf = "push --force-with-lease --force";
        d = "diff";
        a = "add";
        s = "status";
        f = "fetch";
        t = "tag";
        bl = "blame -w -C -C -C";
        l = "log --graph --pretty='%Cred%h%Creset - %C(bold blue)<%an>%Creset %s%C(yellow)%d%Creset %Cgreen(%cr)' --abbrev-commit --date=relative";
        fixup = "commit --fixup";
        pr-init = ''
          !git fetch upstream HEAD && git checkout upstream/HEAD -b $1
        '';
        pr-diff = "diff upstream/HEAD..";
        pr-log = "l upstream/HEAD..";
        pr-edit = "rebase --interactive --autosquash --rerere-autoupdate --rebase-merges --fork-point upstream/HEAD";
        pr-clean = "rebase --autosquash --rerere-autoupdate --empty drop --no-keep-empty --fork-point upstream/HEAD";
        pr-update = "pull --rebase=merges upstream HEAD";
        pr-bisect = "!git bisect start && git bisect bad HEAD; git bisect good $(git merge-base --fork-point upstream/HEAD HEAD)";
      };
      ignores = [
        "vendor"
        "workspace.code-workspace"

        # Always ignore devenv.sh temporary files.
        ".devenv"
        ".devenv.flake.nix"
      ];
      extraConfig = {
        init.defaultBranch = "main";

        core.editor = "code --wait";

        # Show diffs with syntax highlighting.
        diff.external = "${pkgs.difftastic}/bin/difft";

        # Use saner diff prefixes than a/ and b/.
        diff.mnemonicPrefix = true;

        diff.algorithm = "patience";

        # Show original in-between ours and theirs.
        merge.conflictstyle = "diff3";

        # Show moved lines in diff.
        diff.colorMoved = "zebra";

        push.default = "current";
        push.autoSetupRemote = true;
        pull.rebase = false;

        url."git@github.com:".insteadOf = [
          # Normalize GitHub URLs to SSH to avoid authentication issues with HTTPS.
          "https://github.com/"

          # Allows typing `git clone github:owner/repo`.
          "github:"
        ];

        # Sort last committed branches to top.
        branch.sort = "-committerdate";

        # Sort highest version to top.
        tag.sort = "-v:refname";

        # Record and replay conflict resolutions.
        rerere.enabled = true;

        # Show diff in commit message editor.
        commit.verbose = true;

        # Sign commits using SSH public key.
        gpg.format = "ssh";
        user.signingkey = "~/.ssh/github_ed25519.pub";
        commit.gpgSign = true;
        tag.gpgSign = true;
        gpg.program = "${pkgs.gnupg}/bin/gpg2";

        # Avoid hint: use --reapply-cherry-picks to include skipped commits
        advice.skippedCherryPicks = false;

        # Avoid hint: use git switch -c <new-branch-name> to retain commits
        advice.detachedHead = false;

        # Source: https://github.com/rust-lang/cargo/issues/3381#issuecomment-1193730972
        # avoid issues where the cargo-edit tool tries to clone from a repo you do not have WRITE access to.
        # we already use SSH for every github repo, and so this puts the clone back to using HTTPS.
        url."https://github.com/rust-lang/crates.io-index".insteadOf = "https://github.com/rust-lang/crates.io-index";

        # avoid issues where the `cargo audit` command tries to clone from a repo you do not have WRITE access to.
        # we already use SSH for every github repo, and so this puts the clone back to using HTTPS.
        url."https://github.com/RustSec/advisory-db".insteadOf = "https://github.com/RustSec/advisory-db";

        absorb.maxStack = 100;
      };
    };
    programs.gh = {
      enable = true;
      settings = {
        # See https://github.com/nix-community/home-manager/issues/4744
        version = "1";
        editor = "code --wait";
      };
    };
    programs.jq.enable = true;
    programs.neovim.enable = true;
    programs.nix-index.enable = true;
    home.sessionVariables = {
      BROWSER = "chromium";
    };
    programs.direnv = {
      enable = true;
      nix-direnv.enable = true;

      # Store .envrc files outside of project directories.
      # Source: https://github.com/nix-community/nix-direnv#storing-direnv-outside-the-project-directory
      stdlib = builtins.readFile ./direnvrc;
    };
    programs.htop.enable = true;

    home.stateVersion = "21.03";
  };
}