version given as non-existent even though it exists

[AugustoMegener]

I'm trying to start a cc addon project, but the implementation doesn't want to work, it doesn't identify the address even though I'm using the exact same format as the cc readme and the version exists, so I copied it from AP and it still doesn't work, how come it works on AP and doesn't work for me? It doesn't make sense

I'm using minecraft 1.20.1, forge 47.3.7 and cc 1.110.0. I'm also using kotlin for forge

plugins {
    id 'eclipse'
    id 'idea'
    id 'org.jetbrains.kotlin.jvm' version '1.8.22'
    id 'net.minecraftforge.gradle' version '[6.0.16,6.2)'
    id 'org.parchmentmc.librarian.forgegradle' version '1.+'
}


group = mod_group_id
version = mod_version

base {
    archivesName = mod_id
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(17)
}

minecraft {
    
    runs {

        configureEach {

            property 'mixin.env.remapRefMap', 'true'
            property 'mixin.env.refMapRemappingFile', "${buildDir}/createSrgToMcp/output.srg"

            workingDirectory project.file('run')

       

            mods {
                "${mod_id}" {
                    source sourceSets.main
                }
            }
        }

        client {

        }

        server {
            property 'forge.enabledGameTestNamespaces', mod_id
            args '--nogui'
        }

      
        gameTestServer {
            property 'forge.enabledGameTestNamespaces', mod_id
        }

        data {
           
            args '--mod', mod_id, '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')
        }
    }
}


sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {


    maven {
        name = 'Kotlin for Forge'
        url = 'https://thedarkcolour.github.io/KotlinForForge/'
        content { includeGroup "thedarkcolour" }
    }
}

dependencies {
    
    minecraft "net.minecraftforge:forge:${minecraft_version}-${forge_version}"
    implementation "thedarkcolour:kotlinforforge:$kff_version"


    compileOnly "cc.tweaked:cc-tweaked-$minecraft_version-core-api:$cctVersion"
    compileOnly fg.deobf("cc.tweaked:cc-tweaked-$minecraft_version-forge-api:$cctVersion")
    runtimeOnly fg.deobf("cc.tweaked:cc-tweaked-$minecraft_version-forge:$cctVersion")
   
}

compileKotlin {
    kotlinOptions.jvmTarget = "17"
}


tasks.named('processResources', ProcessResources).configure {
    var replaceProperties = [minecraft_version   : minecraft_version, minecraft_version_range: minecraft_version_range,
                             forge_version       : forge_version, forge_version_range: forge_version_range,
                             loader_version_range: loader_version_range,
                             mod_id              : mod_id, mod_name: mod_name, mod_license: mod_license, mod_version: mod_version,
                             mod_authors         : mod_authors, mod_description: mod_description,]

    inputs.properties replaceProperties

    filesMatching(['META-INF/mods.toml', 'pack.mcmeta']) {
        expand replaceProperties + [project: project]
    }
}

tasks.named('jar', Jar).configure {
    manifest {
        attributes(["Specification-Title"     : mod_id,
                    "Specification-Vendor"    : mod_authors,
                    "Specification-Version"   : "1", // We are version 1 of ourselves
                    "Implementation-Title"    : project.name,
                    "Implementation-Version"  : project.jar.archiveVersion,
                    "Implementation-Vendor"   : mod_authors,
                    "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")])
    }

    finalizedBy 'reobfJar'
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

org.gradle.jvmargs=-Xmx3G
org.gradle.daemon=false
minecraft_version=1.20.1
minecraft_version_range=[1.20.1,1.21)
forge_version=47.3.7
forge_version_range=[47,)
loader_version_range=[47,)

kff_version=4.3.0

cctVersion=1.110.0

mapping_version=1.20.1

mod_id=oc2cc

mod_name=OC2r: CC Bridge

mod_license=MIT

mod_version=0.0.1-alpha

mod_group_id=net.kitowashere

mod_authors=KitoWasHere

log.txt

[SquidDev]

It looks like you're missing the repository declaration. You'll also need to add the following to your build.gradle file:

repositories {
  maven {
    url "https://maven.squiddev.cc"
    content {
      includeGroup("cc.tweaked")
    }
  }
}