forked from TNG/junit-dataprovider
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
202 lines (174 loc) · 6.29 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
apply plugin: 'com.github.kt3k.coveralls'
apply plugin: 'cpd'
apply plugin: 'eclipse'
apply plugin: 'groovy'
apply plugin: 'jacoco'
apply plugin: 'java'
apply plugin: 'findbugs'
buildscript {
repositories {
mavenCentral()
}
dependencies {
classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.0.0'
classpath 'de.aaschmid.gradle.plugins:gradle-cpd-plugin:0.1'
}
}
archivesBaseName = 'junit-dataprovider'
description = 'A TestNG like dataprovider runner for JUnit having a simplified syntax compared to all the existing JUnit features.'
group = 'com.tngtech.java'
version = '1.9.4-SNAPSHOT'
sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_5
ext {
isBuildOnJenkins = System.env['BUILD_TAG']?.startsWith('jenkins-') ?: false
}
if (!hasProperty('junitVersion')) { // set default junit version if not set via command line
ext.junitVersion = '4.8.2'
}
ext.skipFindBugs = hasProperty('skipFindBugs')
println "Using junit version ${junitVersion} for current build (skipFindBugs = ${skipFindBugs})."
repositories {
mavenCentral()
}
dependencies {
compile group: 'junit', name: 'junit-dep', version: junitVersion
compile group: 'com.google.code.findbugs', name: 'annotations', version: '2.0.1'
testCompile group: 'org.codehaus.groovy', name: 'groovy', version: '2.0.8'
testCompile group: 'org.assertj', name: 'assertj-core', version: '1.2.0'
testCompile group: 'org.mockito', name: 'mockito-core', version: '1.9.5'
}
task wrapper(type: Wrapper) {
gradleVersion = '2.3'
}
task jenkinsTest {
// required due to jenkins fails if test output is not up to date :(
// Solution found on http://www.practicalgradle.org/blog/2011/06/incremental-tests-with-jenkins/
inputs.files test.outputs.files
enabled = isBuildOnJenkins
doLast {
def timestamp = System.currentTimeMillis()
test.getReports().getJunitXml().getDestination().eachFile{ it.lastModified = timestamp }
}
}
build.dependsOn(jenkinsTest)
jar {
manifest {
attributes (
'Built-By': "Gradle ${gradle.gradleVersion}",
'Built-Date': new Date(), // TODO destroys incremental build feature
'Specification-Title': 'JUnit dataprovider',
'Specification-Version': version,
'Specification-Vendor': 'TNG Technology Consulting GmbH',
'Implementation-Title': 'JUnit dataprovider',
'Implementation-Version': version,
'Implementation-Vendor': 'TNG Technology Consulting GmbH',
'Issue-Tracker': 'https://github.com/TNG/junit-dataprovider/issues',
'Copyright': "${new Date().year} TNG Techology Consulting GmbH",
'License': 'Apache License v2.0, January 2004'
)
}
}
task javadocJar(type: Jar, dependsOn: javadoc) {
classifier = 'javadoc'
from javadoc.destinationDir
}
task sourcesJar(type: Jar) {
classifier = 'sources'
from sourceSets.main.allSource
}
test {
ignoreFailures = isBuildOnJenkins
}
jacocoTestReport {
reports {
xml.enabled = true // coveralls plugin depends on xml format report
}
}
jacoco {
toolVersion = '0.7.1.201405082137'
}
findbugs {
if (System.getProperty("java.version")[0..2] in [ '1.5', '1.6' ]) { // FindBugs v3.0.0 does not work with Java < v1.7 :-(
toolVersion = '2.0.3'
} else {
toolVersion = '3.0.0'
}
ignoreFailures = true
}
tasks.withType(FindBugs).each { task ->
task.enabled = !skipFindBugs
}
tasks.cpd {
minimumTokenCount = 25
source = sourceSets.main.java.srcDirs + sourceSets.test.java.srcDirs
}
artifacts {
archives jar
archives javadocJar
archives sourcesJar
}
// -- build and publish artifacts -------------------------------------------------------------------------------------
apply plugin: 'maven'
apply plugin: 'signing'
signing {
// requires gradle.properties, see http://www.gradle.org/docs/current/userguide/signing_plugin.html
required {
gradle.taskGraph.hasTask('uploadArchives')
}
sign configurations.archives
}
if (!hasProperty('sonatypeUsername')) {
ext.sonatypeUsername = ''
}
if (!hasProperty('sonatypePassword')) {
ext.sonatypePassword = ''
}
uploadArchives {
repositories {
mavenDeployer {
beforeDeployment { deployment ->
signing.signPom(deployment)
}
repository(url: 'https://oss.sonatype.org/service/local/staging/deploy/maven2/') {
// username and password from gradle.properties
authentication(userName: sonatypeUsername, password: sonatypePassword )
}
snapshotRepository(url: 'https://oss.sonatype.org/content/repositories/snapshots/') {
authentication(userName: sonatypeUsername, password: sonatypePassword )
}
pom {
project {
name 'junit-dataprovider'
packaging 'jar'
description 'A TestNG like dataprovider runner for JUnit'
url 'https://github.com/TNG/junit-dataprovider'
scm {
url 'scm:[email protected]:TNG/junit-dataprovider.git'
connection 'scm:[email protected]:TNG/junit-dataprovider.git'
developerConnection 'scm:[email protected]:TNG/junit-dataprovider.git'
}
licenses {
license {
name 'The Apache Software License, Version 2.0'
url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
distribution 'repo'
}
}
developers {
developer {
id 'aaschmid'
name 'Andreas Schmid'
}
}
}
whenConfigured { pom ->
pom.dependencies.find{ dep -> dep.groupId == 'junit' && dep.artifactId == 'junit-dep' }.with {
version = '[4.8.2,4.11]'
scope = 'provided'
}
pom.dependencies.removeAll(pom.dependencies.findAll{ dep -> dep.scope in [ 'compile', 'test' ] })
}
}
}
}
}