-
Notifications
You must be signed in to change notification settings - Fork 0
/
email_vis_-_processing.txt
275 lines (228 loc) · 6.48 KB
/
email_vis_-_processing.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
/* JS INTEGRATION
* ============================================================ */
// credit: http://processingjs.nihongoresources.com/interfacing/
interface JavaScript {
int getSent(int contactId);
int getReceived(int contactId);
boolean getOn(int contactId);
String getLabel(int contactId);
Object[] getContactsByMostTraffic();
}
JavaScript js = null;
void setJavaScript(JavaScript jsP) {
js = jsP;
}
// endcredit
/* GLOBAL VARIABLES
* ============================================================ */
// constants
color backgroundColor = color(255);
int time = 20;
PVector center;
int buffer = 50;
int radius = 640;
int padding = 200;
// js inputs
// MUST BE SET FIRST
// int numContacts
// objects
Contact you;
Contact[] contacts;
/* DRAWING FUNCTIONS
* ============================================================ */
/* Setup
* ------------------------------------------------------------ */
void setup() {
// display
size(radius + padding, radius + padding);
smooth();
background(backgroundColor);
// variables
center = new PVector(0, 0);
// objects
color yourColor = color(255, 238, 102);
you = new Contact(
/* id = */ -1,
/* stroke color = */ yourColor,
/* fill color = */ yourColor,
/* size = */ 24,
/* start location = */ center.get(),
/* angle = */ new PVector(0, 0)
);
// place each contact in center w/ default size
contacts = new Contact[numContacts];
for (int i = 0; i < numContacts; i++) {
// PVector.fromAngle not implemented in processing.js
// PVector angle = PVector.fromAngle(PI * 2 / numContacts * i);
PVector angle = new PVector((float) Math.cos(PI * 2 / numContacts * i),
(float) Math.sin(PI * 2 / numContacts * i));
PVector start = angle.get();
int magnitude = 0;
start.mult(magnitude);
contacts[i] = new Contact(
/* id = */ i,
/* stroke color = */ color(0),
/* fill color = */ color(0, 20),
/* size = */ 16,
/* start location = */ start,
/* angle = */ angle
);
}
}
/* Draw
* ------------------------------------------------------------ */
void draw() {
// clean the canvas
fill(backgroundColor);
rect(0, 0, (radius+padding)*2, (radius+padding)*2);
translate((radius+padding)/2, (radius+padding)/2);
you.display();
for (int i = 0; i < numContacts; i++) {
contacts[i].next();
if (contacts[i].on) {
contacts[i].display();
}
}
drawLimit(buffer);
drawLimit(radius);
if (frameCount % time == 0) {
updateContacts();
}
}
void drawLimit(diameter) {
// show current iteration
ellipseMode(CENTER);
stroke(27, 135, 224);
noFill();
ellipse(center.x, center.y, diameter, diameter);
}
/* HELPER FUNCTIONS
* ============================================================ */
/* contacts[] Helper Functions
* ------------------------------------------------------------ */
void advanceContacts() {
for (int i = 0; i < numContacts; i++) {
contacts[i].next();
}
}
// get size + velocity from JS
void updateContacts() {
int[] positions = new int[numContacts];
int largestPos = 0;
int smallestPos = MAX_INT;
int[] sizes = new int[numContacts];
int largestSize = 0;
int smallestSize = MAX_INT;
int[] contactTotals = new int[numContacts];
int largestTotal = 0;
int smallestTotal = MAX_INT;
// get info and find ranges
for (int i = 0; i < numContacts; i++) {
Contact c = contacts[i];
int curPos = (int) js.getSent(i);
positions[i] = curPos;
if (curPos > largestPos) {
largestPos = curPos;
}
if (curPos < smallestPos) {
smallestPos = curPos;
}
int curSize = (int) js.getReceived(i);
sizes[i] = curSize;
if (curSize > largestSize) {
largestSize = curSize;
}
if (curSize < smallestSize) {
smallestSize = curSize;
}
int curTotal = curPos + curSize;
contactTotals[i] = curTotal;
if (curTotal > largestTotal) {
largestTotal = curTotal;
}
if (curTotal < smallestTotal) {
smallestTotal = curTotal;
}
c.sent = curPos;
c.received = curSize;
}
for (int i = 0; i < numContacts; i++) {
Contact c = contacts[i];
// position
// js.console.log(smallestTotal + ", " + largestTotal + ", " + contactTotals[i]);
int pos = normalize(
positions[i],
smallestPos,
largestPos,
c.magLowerLimit,
c.magUpperLimit
);
c.updatePosition( pos );
// size
// js.console.log(smallestTotal + ", " + largestTotal + ", " + contactTotals[i]);
int size = normalize(
sizes[i],
smallestSize,
largestSize,
c.sizeLowerLimit,
c.sizeUpperLimit
);
c.updateSize( size );
// color
// js.console.log(i + ", " + smallestTotal + ", " + largestTotal + ", " + contactTotals[i]);
int lower = 100;
int upper = 225;
int b = normalize(
contactTotals[i],
smallestTotal,
largestTotal,
lower,
upper
);
int g = normalize(
positions[i],
smallestPos,
largestPos,
lower,
upper
);
int r = normalize(
sizes[i],
smallestSize,
largestSize,
lower,
upper
);
c.fillColor = color(r, g, b, 100);
// on / off
c.on = js.getOn(i); // TODO: make into bool (js sometimes gives string)
}
}
void highlightContact(int contactId) {
contacts[contactId].highlight = true;
}
void unHighlightContact(int contactId) {
contacts[contactId].highlight = false;
}
/* Math Helper Functions
* ------------------------------------------------------------ */
// normalize
// - [smallestPos...largestPos] to [lower...upper]
// - http://stackoverflow.com/questions/1471370/normalizing-from-0-5-1-to-0-1
// - see the last answer
//
// 1. shift the range to [0...x] via subtraction
// 2. scale the range to [0...1] via division
// 3. scale the range to [0...D-C] via multiplication
// so it has the length of the new range (D-C)
// 4. shift the range to [C...D] via addition
int normalize(int n, int fromLow, int fromHigh, int toLow, int toHigh) {
if (n < fromLow || n > fromHigh) {
return -1;
}
n -= fromLow;
n /= (fromHigh - fromLow); // from length
n *= (toHigh - toLow); // to length
n += toLow;
return n;
}