build.gradle

import static java.lang.System.getenv

buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath(group: 'org.jfrog.buildinfo', name: 'build-info-extractor-gradle', version: '3.0.1')
    }
}

allprojects {
    apply plugin: 'idea'
    apply plugin: 'maven-publish'
    apply plugin: 'com.jfrog.artifactory'

    group = 'com.jfrog.bintray.client'

    artifactory {
        contextUrl = 'https://oss.jfrog.org'
        resolve {
            repository {
                repoKey = 'libs-release'
            }
        }

        publish {
            repository {
                repoKey = 'oss-snapshot-local'   //The Artifactory repository key to publish to
                username = project.hasProperty('bintrayUser') ? project.bintrayUser : getenv()['BINTRAY_USER']
                password = project.hasProperty('bintrayKey') ? project.bintrayKey : getenv()['BINTRAY_KEY']
            }
            defaults {
                publications 'main'
            }
        }
    }
}

artifactoryPublish.skip = true

subprojects() {
    apply plugin: 'java'

    sourceCompatibility = 1.5
    targetCompatibility = 1.5

    dependencies {
        compile 'joda-time:joda-time:2.3'
    }

    task sourcesJar(type: Jar) {
        from sourceSets.main.allSource
        classifier = 'sources'
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier = 'javadoc'
        from javadoc.destinationDir
    }

    task testResultsZip(type: Zip) {
        classifier = 'testreports'
        from testReportDir

    }

    test {
        finalizedBy(testResultsZip)
        jvmArgs (['-Dorg.apache.commons.logging.Log=org.apache.commons.logging.impl.SimpleLog',
                '-Dorg.apache.commons.logging.simplelog.showdatetime=true',
                '-Dorg.apache.commons.logging.simplelog.log.org.apache.http=DEBUG',
                '-Dorg.apache.commons.logging.simplelog.log.org.apache.http.wire=ERROR'])
        testLogging {
            exceptionFormat "full"
            events "started", "passed", "skipped", "failed", "standardOut", "standardError"
            minGranularity 0
        }
    }


    publishing {
        publications {
            main(MavenPublication) {
                from components.java
                artifact sourcesJar
                artifact javadocJar
                if (testResultsZip.archivePath.exists()) {
                    artifact testResultsZip
                }

                pom.withXml {
                    asNode().with {
                        appendNode('packaging', 'jar')
                        appendNode('name', 'Bintray Java client')
                        appendNode('description', 'Java client for working with Bintray')
                        appendNode('url', 'https://github.com/bintray/bintray-client-java')
                        appendNode('licenses').with {
                            appendNode('license').with {
                                appendNode('name', 'The Apache Software License, Version 2.0')
                                appendNode('url', 'http://www.apache.org/licenses/LICENSE-2.0')
                            }
                        }
                        appendNode('developers').with {
                            appendNode('developer').with {
                                appendNode('id', 'NoamTenne')
                                appendNode('name', 'Noam Tenne')
                                appendNode('email', 'NoamT@jfrog.com')
                            }
                            appendNode('developer').with {
                                appendNode('id', 'jbaruch')
                                appendNode('name', 'Baruch Sadogursky')
                                appendNode('email', 'jbaruch@jfrog.com')
                            }
                        }
                        appendNode('scm').with {
                            appendNode('connection', 'git@github.com:JFrogDev/bintray/bintray-client-java.git')
                            appendNode('developerConnection', 'git@github.com:bintray/bintray-client-java.git')
                            appendNode('url', 'https://github.com/bintray/bintray-client-java')
                        }
                    }
                    asNode().dependencies.'*'.findAll() {
                        it.scope.text() == 'runtime' && project.configurations.compile.allDependencies.find { dep ->
                            dep.name == it.artifactId.text()
                        }
                    }.each() {
                        it.scope*.value = 'compile'
                    }
                }
            }
        }
    }
}

project(':bintray-client-java-service') {
    apply plugin: 'groovy'

    dependencies {
        compile project(':bintray-client-java-api')
        compile localGroovy()
        compile "org.codehaus.gpars:gpars:1.2.1"
        compile 'org.codehaus.groovy.modules.http-builder:http-builder:0.7.1'
        testCompile("org.spockframework:spock-core:0.7-groovy-2.0") {
            exclude module: 'groovy-all'
            //localGroovy and spock groovy will probably conflict. Both are 2.x, we're good.
        }
        testCompile group: 'com.timgroup', name: 'jgravatar', version: '1.0'
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.1'
}

idea {
    project {
        jdkName = '1.7'
        languageLevel = '1.5'
        wildcards += '?*.gradle'
        ipr {
            withXml { provider ->
                def node = provider.asNode()
                // Use git
                def vcsConfig = node.component.find { it.'@name' == 'VcsDirectoryMappings' }
                vcsConfig.mapping[0].'@vcs' = 'Git'
            }
        }
    }
}