build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

// To avoid manually setting the same values in all Android modules, set the value on the root
// project and then reference this from the modules
ext {
    githubUrl = 'https://github.com/francoiscampbell/RxPlayServices'
    gitUrl = "${githubUrl}.git"
    gitTag = "v$version"

    projectFriendlyName = 'RxPlayServices'
    projectDescription = 'Library that wraps Google Play services APIs using RxJava'

    groupId = 'xyz.fcampbell.rxplayservices'
    versionName = '0.5.0'

    minSdkVersion = 11
    compileSdkVersion = 24
    targetSdkVersion = 24
    buildToolsVersion = "24.0.2"

    vGooglePlayServices = '10.0.1'
    vRxJava = '2.0.4'

    vTestSupportLib = '0.5'
}

buildscript {
    ext {
        vAndroidGradlePlugin = '2.2.3'
        vKotlin = '1.0.6'

        vDokkaPlugin = '0.9.13'
        vAndroidMavenGradlePlugin = '1.5'
        vGradleBintrayPlugin = '1.7.3'

        vDexcount = '0.6.2'
    }
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:$vAndroidGradlePlugin"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$vKotlin"

        classpath "org.jetbrains.dokka:dokka-android-gradle-plugin:$vDokkaPlugin"
        classpath "com.github.dcendents:android-maven-gradle-plugin:$vAndroidMavenGradlePlugin"
        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:$vGradleBintrayPlugin"
    }
}

def isReleaseBuild() {
    return version.contains("SNAPSHOT") == false
}

def getArtifactId(String projectName) {
    return rootProject.name.toLowerCase() + (projectName == 'library' ? '' : ('-' + projectName))
}

allprojects {
    version = rootProject.ext.versionName
    group = rootProject.ext.groupId

    repositories {
        mavenCentral()
        jcenter()
    }
}

task wrapper(type: Wrapper) {
    distributionUrl = "https://services.gradle.org/distributions/gradle-2.14.1-all.zip"
}