build.gradle

/*
 * Copyright and related rights waived via CC0
 *
 * You should have received a copy of the CC0 legalcode along with this
 * work. If not, see <http://creativecommons.org/publicdomain/zero/1.0/>.
 */

plugins {
    id 'base'
    id "com.diffplug.spotless" version "6.3.0"
    id "org.graalvm.internal.tck-harness"
}

allprojects {
    repositories {
        mavenCentral()
        mavenLocal()
    }
}

// NOTE: this version serves only as a placeholder and will be overridden by the CI when creating a new release
project.version("1.0.0-SNAPSHOT")

// gradle check
spotless {
    json {
        target(
                tck.metadataRoot.map { it.toString() +  '/**/*.json' }.get(),
                tck.testRoot.map { it.toString() + '/**/*.json' }
        )
        targetExclude(
                tck.testRoot.map { it.toString()  + '/**/build/**/*.json' },
                tck.repoRoot.map { it.toString() + '/.github/**/*.json' }
        )
        gson()
            .indentWithSpaces(2)
            .sortByKeys()
            .version("2.9.0")
    }
}

// gradle package
tasks.register('package', Zip) { task ->
    String outputFileName = "graalvm-reachability-metadata-${project.version}.zip"
    task.setDescription("Packages current repository to 'build/${outputFileName}'")
    task.setGroup(PublishingPlugin.PUBLISH_TASK_GROUP)
    task.archiveFileName = outputFileName
    task.destinationDirectory = layout.buildDirectory
    from(tck.metadataRoot)
}