build.gradle

plugins {
    id "groovy"
    id "java-library"
    id "war"
    id "idea"
    id "org.grails.grails-plugin"
    id "org.grails.internal.grails-plugin-publish"
    id "application"
    id "eclipse"
}

group "org.grails.plugins"

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
    maven { url "https://repo.grails.org/grails/core" }
}

dependencyManagement {
    imports {
        mavenBom "org.grails:grails-bom:$grailsVersion"
    }
    applyMavenExclusions false
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-logging'
    implementation "org.springframework.boot:spring-boot-starter-actuator"
    implementation "org.springframework.boot:spring-boot-autoconfigure"
    implementation "org.springframework.boot:spring-boot-starter-tomcat"

    implementation "org.grails:grails-web-boot"
    implementation "org.grails:grails-dependencies"

    api 'net.sf.opencsv:opencsv:2.3'

    api 'com.lowagie:itext:2.1.7'
    api "com.lowagie:itext-rtf:2.1.7"
    runtimeOnly 'xerces:xercesImpl:2.12.2'

    api 'org.odftoolkit:simple-odf:0.6.6'
    api 'net.sourceforge.jexcelapi:jxl:2.6.12'
    api 'commons-beanutils:commons-beanutils:1.9.4'
    api 'commons-codec:commons-codec:1.17.0'

    testCompileOnly "org.grails:grails-plugin-testing"
}

jar {
    exclude 'gsp**'

    List excludes = ['UrlMappings', 'TestController']
    excludes.each {
        exclude "**/${it}*.class"
    }
    eachFile { copyDetails ->
        if (copyDetails.path.contains('grails-plugin.xml')) {
            filter { line -> excludes.find{line.contains(it)}? null : line}
        }
    }
    archiveClassifier=''
}

grailsPublish {
    license {
        name = 'Apache-2.0'
    }

    title = "Grails Export Plugin"
    desc = "This plugin offers export functionality supporting different formats e.g. CSV, Excel, Open Document Spreadsheet, PDF and XML and can be extended to add additional formats."

    developers = [  graemerocher: 'Graeme Rocher',
                    puneetbehl: 'Puneet Behl',
                    nwwells: 'Nathan Wells',
                    tulu: 'Ruben',
                    arturoojeda: 'Arturo Ojeda López',
                    fabiooshiro: 'Fabio Issamu Oshiro',
                    ddelponte: 'Dean Del Ponte',
                    cristallo: 'Cristiano Limiti',
                    mirweb: 'Mirko Weber',
                    joasgarcia: 'Joás Garcia',
                    frangarcia: 'Fran García',
                    dustindclark: 'Dustin Clark' ]
}