build.gradle

plugins {
    id "org.jetbrains.kotlin.jvm" version "1.4.10"
    id 'maven'
    id 'signing'
}

group 'com.natpryce'

version(hasProperty("-version") ? property("-version") : "SNAPSHOT")
println "building version ${version}"

repositories {
    mavenCentral()
}

dependencies {
    compileOnly "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    compileOnly "org.jetbrains.kotlin:kotlin-reflect"

    testImplementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    testImplementation "org.jetbrains.kotlin:kotlin-reflect"
    testImplementation "org.jetbrains.kotlin:kotlin-test"
    testImplementation 'junit:junit:4.12'
}

jar {
    manifest {
        attributes 'Implementation-Title': 'hamkrest',
                'Implementation-Vendor': 'com.natpryce',
                'Implementation-Version': version
    }
}

task sourcesJar(type: Jar) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives sourcesJar
}

task javadocJar(type: Jar) {
    archiveClassifier = 'javadoc'
    from 'build/javadoc'
}

test {
    include 'com/natpryce/hamkrest/**'
    scanForTestClasses true
    reports {
        junitXml.enabled = true
        html.enabled = true
    }

    beforeTest { desc ->
        print "${desc.className.substring("com.natpryce.hamkrest.".length())}: ${desc.name.replace("_", " ")}"
    }
    afterTest { desc, result ->
        println " -> ${result.resultType}"
    }
}

artifacts {
    archives sourcesJar, javadocJar
}

signing {
    required { hasProperty("sign") || gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

task ossrhAuthentication {
    doFirst {
        if (!(project.hasProperty('ossrh.username') && project.hasProperty('ossrh.password'))) {
            throw new InvalidUserDataException("no OSSRH username and/or password!")
        }
    }
}

uploadArchives {
    dependsOn ossrhAuthentication

    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: project.properties["ossrh.username"],
                        password: project.properties["ossrh.password"])
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: project.properties["ossrh.username"],
                        password: project.properties["ossrh.password"])
            }

            pom.project {
                name 'HamKrest'
                packaging 'jar'
                description 'Matcher library for Kotlin. A port of Hamcrest, made more Kotlin-esque.'
                url 'https://github.com/npryce/hamkrest'

                scm {
                    connection 'git@github.com:npryce/hamkrest.git'
                    url 'https://github.com/npryce/hamkrest'
                }

                licenses {
                    license {
                        name 'Apache 2.0'
                        url 'http://opensource.org/licenses/Apache-2.0'
                    }
                }

                developers {
                    developer {
                        id 'npryce'
                        name 'Nat Pryce'
                    }
                    developer {
                        id 'dmcg'
                        name 'Duncan McGregor'
                    }
                }
            }
        }
    }
}