build.gradle

apply plugin: 'groovy'
apply plugin: 'maven-publish'

description = 'Gradle Buster plugin for running busterjs tests'
group = 'org.gradle.buster'
version = '0.1.1'

repositories {
	mavenCentral()
}


configurations {
    sourceArchives
}

dependencies {
	compile gradleApi(), 'net.sf.jpathwatch:jpathwatch:0.95'
	groovy localGroovy()

	testCompile 'org.spockframework:spock-core:0.7-groovy-1.8', 'cglib:cglib-nodep:2.2.2'
	
}

task sourceJar(type: Jar) {
    from sourceSets.main.allSource
}


publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            artifact sourceJar {
                classifier "sources"
            }
        }

    }
    repositories{
        maven {
            url "https://api.bintray.com/maven/rundis/maven/gradle-buster-plugin"
                    credentials {
                        username = bintray_username
                        password = bintray_api_key
                    }
        }
    }
}



sourceSets {
    integrationTest {
        groovy {
            srcDir 'src/integrationtest/groovy'
        }
        resources {
            srcDir 'src/integrationtest/resources'
        }
        compileClasspath += sourceSets.test.runtimeClasspath
    }
}

task integrationTest(type: Test) {
    description = "Runs Integration Tests"
    dependsOn 'jar'
    testClassesDir = sourceSets.integrationTest.output.classesDir
    classpath += sourceSets.integrationTest.runtimeClasspath
}
build.dependsOn integrationTest



task wrapper(type: Wrapper) {
    gradleVersion = '1.6'
}