-
Notifications
You must be signed in to change notification settings - Fork 0
/
estimate.gp
283 lines (230 loc) · 8.27 KB
/
estimate.gp
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
read("bkzsim.gp");
read("search.gp");
log2(x) = {if(x == 0, 0, log(x)/log(2))};
/* Parameters */
USE_SIMULATOR = 0;
IGNORE_TOURS = 1;
TOUR_CAP = 5;
OPTIMIZE_M = 1;
MAXDEPTH = -1; /* Infinite */
/* Wrappers around CN11 simulator */
CN11SimHermite(d, b) = {
/* Simulate BKZ-b in dimension d and return resulting root hermite factor */
simulate(d,b,0,TOUR_CAP)[2];
}
CN11SimIter(d, b, h) = {
/* Simulate BKZ-b in dimension d and return number of tours required to
* reach root hermite factor h */
if(IGNORE_TOURS,
0,
if(!USE_SIMULATOR,
1,
simulate(d, b, h, TOUR_CAP)[3]));
}
/* Cost Functions */
QuadEnumCN11(b) = { 0.000784314*b^2 + 0.366078*b - 6.125; }
EnumCN11(b) = { 0.270189*log(2)*b*log2(b) - 1.0192*b + 16.10; }
EnumCN11Simple(b) = { b*log2(b)/(2*exp(1)) - b + 16; }
QEnumCN11(b) = {
my(C);
C = 1/2 * EnumCN11(b);
if(MAXDEPTH < 0 || C < MAXDEPTH,
return(C),
return(MAXDEPTH + 2*(C-MAXDEPTH)));
}
SieveNV08(b) = { 0.415*b }
SieveBGJ15(b) = { 0.311*b }
SieveD18(b) = { (0.2075 + 0.142)*b }
SieveBDGL16(b) = { b*log2(sqrt(3/2)); }
QSieveLaa15(b) = { b*log2(sqrt(13/9)); }
SieveSpace(b) = { b*log2(sqrt(4/3)); }
/* Table indicating which cost functions will be used */
COSTFNS = /* enabled? */
[["Quad Enum [CN11]", QuadEnumCN11, 0],\
["Enum [CN11]", EnumCN11, 0],\
["Enum [CN11]", EnumCN11Simple, 0],\
["Quantum CN11Enum", QEnumCN11, 0],\
["SieveNV08", SieveNV08, 1],\
["SieveBGJ15", SieveBGJ15, 0],\
["SieveD18", SieveD18, 1],\
["SieveBDGL16", SieveBDGL16, 1],\
["Quantum LSF Sieve", QSieveLaa15, 0],\
["Sieve vectors", SieveSpace, 0]];
ExpectedCoeffSize(coeffDist) = {
my(len, low);
\\ standard deviation of coeffDist (assumes coeffDist is mean centered)
len = length(coeffDist);
low = -floor(len/2);
sqrt(coeffDist * vector(len, i, (low + i - 1)^2)~);
}
MaxCoeffSize(coeffDist) = {
my(len, low);
len = length(coeffDist);
low = -floor(len/2);
vecmax(vector(#coeffDist, i, if(coeffDist[i] != 0, abs(low + i - 1), 0)));
}
/* MITM / Quantum Search cost */
MITM(coeffDist, k) = {
my(plogp,C);
\\ Assume we can MITM (or quantum search) k coeffs using
\\ 2^{.5 * entropy(coeffDist)} queries
plogp = coeffDist * vector(#coeffDist, i, log2(coeffDist[i]))~;
C = floor(0.5 * k * (-plogp));
if(MAXDEPTH < 0 || C < MAXDEPTH,
return([C,0]),
return([MAXDEPTH, 2*(C-MAXDEPTH)]));
};
/* Lattice Reduction */
GSAHermite(b,useStirling=1) = {
\\ Root hermite factor achieved by BKZ-b under
\\ Geometric Series Assumption
if(useStirling,
((Pi*b)^(1/b) * b / (2*Pi*exp(1)))^(1/(2*b-2)),
exp((1/(b*(b-1)) * lngamma(b/2 + 1) - log(Pi)/(2*b-2))));
};
GSAHeight(d, m, q, h, i) = {
\\ We are 1-indexing so we want
\\ q^(m/d)*h^d at i=1;
\\ q^(m/d)*h^-d at i=d; and
\\ geometric with ratio h^2 between.
q^(m/d) * h^(d - 2*d*(i-1)/(d-1))
}
GSAEnsureHeight(d,m,q,height,index) = {
my(s,h,g);
\\ Find the largest root Hermite factor for which
\\ the "index"-th gram schmidt norm would be greater
\\ than "height"
\\ When index < d/2 approach height from above
\\ When index > d/2 approach height from below
s = if(2*index < d, 1, -1);
g = 10e6;
h = MaxLT((x)->(s*GSAHeight(d, m, q, x/g, index)), s*height, g, 2*g);
1.0*h/g;
}
/* Hybrid Attack
* d: dimension
* q: modulus
* m: log base q of lattice volume
* coeffDist: coefficient distribution of target vector */
HybridHermite(d,m,q,coeffDist) = {
my(minGS, ld);
\\ Set the hermite requirement so that the last
\\ gram schmidt vector (in the reduced block) has length
\\ greater than twice the max coefficient size.
minGS = 2 * MaxCoeffSize(coeffDist);
ld = ((m/d)*log2(q) - log2(minGS))/d;
2^ld
};
HybridBlocksize(d, delta) = {
my(bs, low, high);
/* Do a quick search to narrow range for simulator, if we're using it */
bs = MaxLT((x)->(-GSAHermite(x)), -delta, 2, d);
if(USE_SIMULATOR,
low = max(0, bs - 15);
high = min(d, bs + 15);
bs = MaxLT((x)->(-CN11SimHermite(d, x)), -delta, low, high));
bs + 1;
}
HybridCostEstimate(CostFn,n,maxm,q,coeffDist,k,summarize=0) = {
my(s,m,d,h,bs,iter,cost,costMITM);
s = ExpectedCoeffSize(coeffDist);
m = MaxLT((x)->(/* max-max (m, h). m s.t. b*_1 < q; h s.t. b*_{m+(n-k)} > s */
GSAHeight(x+(n-k), x, q, HybridHermite(x+(n-k), x, q, coeffDist), 1)),
q, 2, maxm);
d = m+(n-k);
h = HybridHermite(d, m, q, coeffDist);
bs = HybridBlocksize(d, h);
iter = CN11SimIter(d,bs,h);
cost = CostFn(bs) + log2(d*iter);
costMITM = MITM(coeffDist, k);
if(summarize,
printf("\tn=%d, m=%d, d=%d, k=%d\n", n, m, d, k);
SummarizeBKZ(CostFn, d, m, q, s, h, bs, iter);
printf("\tCost of MITM-%-4d\t%s\n", k, costMITM));
cost;
}
HybridTradeoff(CostFn,n,maxm,q,coeffDist) = {
MaxLT((k)->(vecsum(MITM(coeffDist,k)) - HybridCostEstimate(CostFn,n,maxm,q,coeffDist,k)), 0, 0, n);
}
/* Primal attack */
PrimalBlocksize(n,m,q,s,usvp=0) = {
my(d,bs,low,high);
if(usvp, d=n+m, d=n+m+1);
bs = MaxLT(/* max blocksize with b*_{d-bs} < s*sqrt{bs} */
(x)->(GSAHeight(d, m, q, GSAHermite(x), d-x)/sqrt(x)), s, 2, d);
if(USE_SIMULATOR, /* Same search using simulator */
low = max(0, bs - 15);
high = min(d, bs + 15);
bs = MaxLT((x)->(GSAHeight(d, m, q, CN11SimHermite(d,x), d-x)/sqrt(x)), s, low, high));
bs + 1; /* Increment bs by 1 to tip height @ d-bs _above_ s*sqrt{bs} */
}
OptimalDim(n,q,h) = { floor(sqrt(n*log(q)/log(h))); }
PrimalCostEstimate(CostFn,n,m,q,coeffDist,usvp=0,summarize=0) = {
my(s,bs,d,h,iter,cost);
s = ExpectedCoeffSize(coeffDist);
\\ Search for b such that s*sqrt(b) < GSAHermite(b)^(2b - d - 1) Vol(L)
bs = PrimalBlocksize(n,m,q,s,usvp);
if(OPTIMIZE_M, /* Try to decrease number of samples */
/* TODO: be smarter here */
m = -n-1 + OptimalDim(n,q,GSAHermite(bs));
bs = PrimalBlocksize(n,m,q,s,usvp);
m = -n-1 + OptimalDim(n,q,GSAHermite(bs));
bs = PrimalBlocksize(n,m,q,s,usvp));
if(usvp, d=n+m, d=n+m+1);
\\h = GSAEnsureHeight(d, m, q, s*sqrt(bs), d-bs);
h = GSAHermite(bs);
iter = CN11SimIter(d,bs,h);
cost = CostFn(bs) + log2(d*iter);
if(summarize,
printf("\tn=%d, m=%d, d=%d\n", n, m, n+m+1, h);
SummarizeBKZ(CostFn, d, m, q, s, h, bs, iter));
cost;
}
SummarizeBKZ(CostFn, d, m, q, s, h, bs, iter) = {
my(cost);
cost = CostFn(bs);
if(USE_SIMULATOR,
printf("\tSimulator suggests %d tours, BKZ-%d → %.5f.\n", iter, bs, h),
/* else */
printf("\tGSA suggests BKZ-%d → %.5f\n", bs, h));
/* endif */
printf("\tFirst block\t\t%8.2f ... %5.2f\n", GSAHeight(d, m, q, h, 1), GSAHeight(d, m, q, h, bs));
printf("\tLast block\t\t%8.2f ... %5.2f\n", GSAHeight(d, m, q, h, d-bs), GSAHeight(d, m, q, h, d));
printf("\tProj. last block\t%8.2f ... %5.2f\n", sqrt(bs)*s, s);
printf("\tCost of SVP-%-5d\t%8.2f\n", bs, cost);
if(!IGNORE_TOURS,
printf("\t... with %d tour(s)\t%8d\n", iter, cost+log2(d*iter)));
}
/* Main */
Run(n, maxm, q, coeffDist, usvp=0, verbose=0) = {
my(costFn, k);
if(verbose,
printf("Cost functions:\n");
j=0;
for(i=1, #COSTFNS, if(COSTFNS[i][3], j+=1;
printf("\t%d) %s : %s\n", j, COSTFNS[i][1], COSTFNS[i][2])));
if(USE_SIMULATOR,
printf("\n- Using BKZ Simulator. "),
printf("\n- Using Gaussian Heuristic and Geometric Series Assumption. "));
printf("(USE_SIMULATOR = %d)\n", USE_SIMULATOR);
if(IGNORE_TOURS,
printf("- Ignoring tour cost. Assuming a single SVP call will suffice. "),
printf("- Including tour cost. Max of %d tour(s). ", TOUR_CAP));
printf("(IGNORE_TOURS = %d)\n\n", IGNORE_TOURS));
for(i=1, #COSTFNS, if(COSTFNS[i][3],
costFn = COSTFNS[i][2];
printf("\n----------------%s-------------------\n", COSTFNS[i][1]);
printf("\nPrimal");
PrimalCostEstimate(costFn,n,maxm,q,coeffDist,usvp,summarize=1);
printf("\nHybrid", COSTFNS[i][1]);
k = HybridTradeoff(costFn,n,maxm,q,coeffDist);
HybridCostEstimate(costFn,n,maxm,q,coeffDist,k,summarize=1)
));
}
RunPrimal(n,maxm,q,coeffDist,costFn,usvp) = {
PrimalCostEstimate(costFn,n,maxm,q,coeffDist,usvp,summarize=0)
}
RunHybrid(n,maxm,q,coeffDist,costFn) = {
k = HybridTradeoff(costFn,n,maxm,q,coeffDist);
HybridCostEstimate(costFn,n,maxm,q,coeffDist,k,summarize=0)
}