build.gradle

apply plugin: 'java'
apply plugin: 'project-report'

repositories {
    maven {
        url 'https://repo.jenkins-ci.org/public/'
    }
}

configurations {
    testPlugins {}
}

configurations.all*.exclude group: 'xalan'

dependencies {

    compile 'org.glassfish.jersey.media:jersey-media-sse:2.25',
            'org.glassfish.jersey.media:jersey-media-json-jackson:2.25'

    testCompile 'org.jvnet:tiger-types:2.2',
                'org.jenkins-ci.main:jenkins-test-harness:2.8',
                "org.jenkins-ci.main:jenkins-war:${jenkinsVersion}:war-for-test@jar"
    testCompile "org.jenkins-ci.main:jenkins-war:${jenkinsVersion}"

    testPlugins 'org.jenkins-ci.modules:pubsub-light:1.3',
                'org.jenkins-ci.plugins:sse-gateway:1.10'
}

task resolveTestPlugins(type: Copy) {
    from configurations.testPlugins
    into new File(sourceSets.test.output.resourcesDir, 'test-dependencies')
    include '*.hpi'
    include '*.jpi'

    doLast {
        def baseNames = source.collect { it.name[0..it.name.lastIndexOf('.')-1] }
        new File(destinationDir, 'index').setText(baseNames.join('\n'), 'UTF-8')
    }
}

test {
    dependsOn tasks.resolveTestPlugins

    exclude '**/XmlOutput.class'

    // set build directory for Jenkins test harness, JENKINS-26331
    systemProperty 'buildDirectory', project.buildDir.absolutePath

    testLogging {
        showStandardStreams = true
    }
}