build.gradle

buildscript {
    repositories {
        google()
        jcenter()
        maven {
            url 'https://api.mapbox.com/downloads/v2/releases/maven'
            authentication {
                basic(BasicAuthentication)
            }
            credentials {
                username = "mapbox"
                password = project.hasProperty('SDK_REGISTRY_TOKEN') ? project.property('SDK_REGISTRY_TOKEN') : System.getenv('SDK_REGISTRY_TOKEN')
            }
        }
    }

    dependencies {
        apply from: "${rootDir}/gradle/dependencies.gradle"

        if (SDK_REGISTRY == 'true') {
            classpath pluginDependencies.mapboxSdkRegistry
        }
    }
}

plugins {
    id 'groovy'
    id 'jacoco'
}

group GROUP
version VERSION_NAME

sourceCompatibility = 1.8

repositories {
    mavenCentral()
    google()
    jcenter()
}

jacoco {
    toolVersion = "0.8.4"
    reportsDir = file("$buildDir/reports/jacoco")
}

jacocoTestReport {
    reports {
        xml.enabled true
        csv.enabled false
        html.enabled true
    }
}

dependencies {
    apply from: "${rootDir}/gradle/dependencies.gradle"

    testImplementation dependenciesList.junit
    implementation gradleApi()
}

apply from: "${rootDir}/gradle/checkstyle.gradle"
apply from: "${rootDir}/gradle/codenarc.gradle"
apply from: "${rootDir}/gradle/sdk-registry.gradle"

afterEvaluate {
    tasks.findByName('check').dependsOn('checkstyle')
}

// TODO Add code coverage tool based on necessity.