Provide version string to ports that do not provide it in cmake

[dalboris]

Without using vcpkg, I usually have access library version in my CMakeLists, like so:

find_package(PythonInterp 3.6 REQUIRED)
find_package(PythonLibs 3.6 REQUIRED)
message(STATUS "Version: ${PYTHON_VERSION_STRING}")

But, when using vcpkg, this doesn't seem to work. Here is an example with FreeType:

find_package(freetype CONFIG REQUIRED)
get_target_property(FREETYPE_INCLUDE_DIRS freetype INTERFACE_INCLUDE_DIRECTORIES)
message(STATUS "FreeType include dirs: ${FREETYPE_INCLUDE_DIRS}")
message(STATUS "FreeType version: ${FREETYPE_VERSION}")
message(STATUS "FreeType version: ${FREETYPE_VERSION_STRING}")
message(STATUS "FreeType version: ${freetype_VERSION}")
message(STATUS "FreeType version: ${freetype_VERSION_STRING}")
message(STATUS "FreeType version: ${Freetype_VERSION}")
message(STATUS "FreeType version: ${Freetype_VERSION_STRING}")
message(STATUS "FreeType version: ${FreeType_VERSION}")
message(STATUS "FreeType version: ${FreeType_VERSION_STRING}")

Output:

-- FreeType include dirs: C:/Users/Boris/vcpkg/installed/x64-windows/include
-- FreeType version:
-- FreeType version:
-- FreeType version:
-- FreeType version:
-- FreeType version:
-- FreeType version:
-- FreeType version:
-- FreeType version:

Is there any way to get those versions for packages installed and found with vcpkg?

[dalboris]

Note: as a workaround, I'm currently doing the following in my CMakeLists (finding and parsing freetype.h), which is a little bit convoluted:

    find_package(freetype CONFIG REQUIRED)
    set(FREETYPE_LIBRARIES freetype)
    get_target_property(_FREETYPE_INCLUDE_DIRS freetype INTERFACE_INCLUDE_DIRECTORIES)
    set(_FREETYPE_H_PATH "")
    foreach(h ${_FREETYPE_INCLUDE_DIRS})
        if(NOT _FREETYPE_H_PATH)
            if (EXISTS "${h}/freetype/freetype.h")
                set(_FREETYPE_H_PATH "${h}/freetype/freetype.h")
            elseif (EXISTS "${h}/freetype.h")
                set(_FREETYPE_H_PATH "${h}/freetype.h")
            endif()
        endif()
    endforeach()
    if(_FREETYPE_H_PATH)
        file(READ "${_FREETYPE_H_PATH}" _FREETYPE_H)
        string(REGEX MATCH "define[ \t]+FREETYPE_MAJOR[ \t]+([0-9]+)" _FREETYPE_MAJOR_MATCH "${_FREETYPE_H}")
        set(FREETYPE_VERSION_MAJOR "${CMAKE_MATCH_1}")
        string(REGEX MATCH "define[ \t]+FREETYPE_MINOR[ \t]+([0-9]+)" _FREETYPE_MINOR_MATCH "${_FREETYPE_H}")
        set(FREETYPE_VERSION_MINOR "${CMAKE_MATCH_1}")
        string(REGEX MATCH "define[ \t]+FREETYPE_PATCH[ \t]+([0-9]+)" _FREETYPE_PATCH_MATCH "${_FREETYPE_H}")
        set(FREETYPE_VERSION_PATCH "${CMAKE_MATCH_1}")
        set(FREETYPE_VERSION_STRING "${FREETYPE_VERSION_MAJOR}.${FREETYPE_VERSION_MINOR}.${FREETYPE_VERSION_PATCH}")
    endif()
    message(STATUS "FreeType version: ${FREETYPE_VERSION_STRING}")

[JackBoosY]

Because freetype doesn't provide its version.
Generally, the version is provided in <PORT>-version.cmake.

[dalboris]

What do you mean exactly by "freetype doesn't provide its version"? The version is in the freetype.h header, and the FindFreetype module built-in CMake provides a FREETYPE_VERSION. So I think the freetype-config.cmake file provided by vcpkg (and any other config file provided by vcpkg) should also provide an easy way to get its version: it's quite an important information to display in the CMake output, or check against.

[JackBoosY]

@dalboris That is provided by cmake instead of freetype. And freetype-config.cmake and other cmake files generated by freetype itself, that is what I said freetype doesn't provide its version.
So I think that's a upstream issue, could you report it to freetype?

Thanks.

[dalboris]

@JackBoosY I still don't understand what you mean by "That is provided by cmake instead of freetype". In my book, freetype does provide a version, and the built-in FindFreetype module of CMake just reads it. Here is content from freetype.h:

*************************************************************************
   *
   * @enum:
   *   FREETYPE_XXX
   *
   * @description:
   *   These three macros identify the FreeType source code version.
   *   Use @FT_Library_Version to access them at runtime.
   *
   * @values:
   *   FREETYPE_MAJOR :: The major version number.
   *   FREETYPE_MINOR :: The minor version number.
   *   FREETYPE_PATCH :: The patch level.
   *
   * @note:
   *   The version number of FreeType if built as a dynamic link library
   *   with the `libtool' package is _not_ controlled by these three
   *   macros.
   *
   */
#define FREETYPE_MAJOR  2
#define FREETYPE_MINOR  4
#define FREETYPE_PATCH  10

The issue is specifically with vcpkg: outside of vcpkg's world, most FindFoobar modules provide a version. But with vcpkg, it seems that its foobar-config.cmake modules don't do it, such as I show here with the freetype-config.cmake module of vcpkg.

So my question is: do the vcpks CMake modules really don't provide a version as CMake variable for the found library? It would seem like a huge oversight: I really expect to be able to do FOOBAR_VERSION after find_package(FooBar), regardless of whether the package was found via a vcpkg module, a built-in module, or a custom FindFooBar.cmake module specifically written for my project. In theory, my CMakeLists.txt file should be agnostic of whether the package was found via vcpkg or not, and when FOOBAR_FOUND is true, then FOOBAR_VERSION should also be set.

[dalboris]

Note in case this was unclear: I want to have access to FOOBAR_VERSION in my CMakeLists.txt, not in my C/C++ code.

[JackBoosY]

FindFreetype.cmake -> https://github.com/Kitware/CMake/blob/master/Modules/FindFreetype.cmake
Export-related cmake codes:
FREETYPE_SOURCE/CMakeList.txt line 566:

  install(
    EXPORT freetype-targets
      DESTINATION ${CONFIG_INSTALL_PATH}
      FILE freetype-config.cmake
      COMPONENT headers)

Usually, when using install(EXPORT), we also need write_basic_package_version_file or reserve a *-version.cmake.in to generate *-version.cmake at the same time. But currently freetype does not.
That caused this issue.

[JackBoosY]

Example:

• https://github.com/OSGeo/PROJ/blob/master/cmake/project-config-version.cmake.in
• https://github.com/uriparser/uriparser/blob/b047fc5db5b848b4d5a44dcb7ee91e4f1cba987f/CMakeLists.txt#L369

[dalboris]

Oh, I see! So you're saying that the freetype-config.cmake file provided by vcpkg isn't actually generated/designed by vcpkg, but comes from freetype? (Question 1)

More specifically, are you saying that in freetype-2.10.2/CMakeLists.txt#L546, if instead of:

install(
    EXPORT freetype-targets
      DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/freetype
      FILE freetype-config.cmake
      COMPONENT headers)

There was:

install(
    EXPORT freetype-targets
      DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/freetype
      FILE freetype-config.cmake
      COMPONENT headers)

write_basic_package_version_file(
    cmake/freetype-config-version.cmake
    VERSION 2.10.2
    COMPATIBILITY SameMajorVersion
)

Then there would auto-magically be a FREETYPE_VERSION_STRING CMake variable available after finding the package with vcpkg? (Question 2)

And you're saying that some (or most?) other foobar-config.cmake provided by vcpkg do expose such FOOBAR_VERSION_STRING? (Question 3)

Anyway, this does mean that Kitware's built-in FindFreeType module is superior than the freetype-config.cmake module provided by vcpkg, regardless of whether this freetype-config.cmake is designed by FreeType itself or by vcpkg. I'd say that if such write_basic_package_version_file() function is missing upstream, it should the role of the package manager to fill the hole: the package manager does know the installed version, and should provide easy ways to access it in CMake. In fact, version management is the primary role of a package manager. At the contrary, it isn't the responsibility of a library (such as FreeType) to provide config files for every build system in existence, although in the specific case of CMake, I would agree it's probably a shared responsibility, since it is nowadays a de-facto standard.

[dalboris]

FYI: I reported this upstream: https://savannah.nongnu.org/bugs/index.php?58935

This is a follow-up of a discussion I just had here:

#12848

The freetype-config.cmake file generated by FreeType's CMakeLists.txt does not contain version info. Therefore, in external projects that "find" FreeType via this freetype-config.cmake file (e.g., find_package(freetype CONFIG REQUIRED)), the freetype_VERSION variable won't be set.

The appropriate approach seems to be to add to CMakeLists.txt something along the lines of:

write_basic_package_version_file(
    ${CMAKE_INSTALL_LIBDIR}/cmake/freetype/freetype-config-version.cmake
    VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}
    COMPATIBILITY SameMajorVersion)

Just after this existing code:

  install(
    EXPORT freetype-targets
      DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/freetype
      FILE freetype-config.cmake
      COMPONENT headers)

Or alternatively, use a freetype-version.cmake.in file to generate a
freetype-version.cmake file at the same time as the freetype-config.cmake
file.

I'm happy to help with with this if provided some guidance on how to
contribute to FreeType (I'm not used to this Savannah system).

[dalboris]

I actually realized that even when FreeType is installed via vcpkg, we can simply do find_package(Freetype REQUIRED) instead of find_package(freetype CONFIG REQUIRED). This will use the built-in CMake FindFreetype module, but it will still find the vcpkg-installed FreeType, with the following differences:

• The imported target will be Freetype::Freetype instead of freetype (which I prefer, for compatibility with built-in FindFreetype)
• FREETYPE_VERSION_STRING is correctly defined

I noticed this because I had the following message in my CI builds, which apparently have a different version of vcpkg (older?):

The package freetype is compatible with built-in CMake targets:

    find_package(Freetype REQUIRED)
    target_link_libraries(main PRIVATE Freetype::Freetype)

This message seems to have been removed on Jan 2020 (#9311) in favor of the more generic find_package(freetype CONFIG REQUIRED) recommendation.

So it isn't really clear to me what's the cleanest approach, but I'm now using find_package(Freetype REQUIRED) which works better in my situation. I'm still keeping this issue open since the version should still probably be available when using find_package(freetype CONFIG REQUIRED) too.

[JackBoosY]

For questions:

1. Yes, freetype should provide it by itself.
2. ${PORT}_VERSION_STRING is always provided by *-config-version.cmake or Find*.cmake. If you use write_basic_package_version_file in CMakelists.txt, cmake will automatically generate *-config-version.cmake.
3. So far, vcpkg does not provide this string, but I think for some ports that do not have this string, vcpkg should provide it in cmake (using vcpkg-toolchain).

[JackBoosY]

Since freetype's CMakelists.txt is maintained by its official, we believe that the cmake files generated by itself are more reasonable and stable than using FindFreetype.cmake. This is why FindFreetype.cmake is deprecated.

[dalboris]

Thank you for your patience and answering my questions, everything seems clear now.

[dalboris]

I am trying to write a patch upstream for FreeType, using write_basic_package_version_file(). Does vcpkg care where is the freetype-config-version.cmake file generated?

When I run mkdir build && cd build && cmake .. on the current freetype source, I see that the following files are generated:

freetype2\build\CMakeFiles\Export\lib\cmake\freetype\freetype-config.cmake
freetype2\build\CMakeFiles\Export\lib\cmake\freetype\freetype-config-debug.cmake
freetype2\build\CMakeFiles\Export\lib\cmake\freetype\freetype-config-minsizerel.cmake
freetype2\build\CMakeFiles\Export\lib\cmake\freetype\freetype-config-release.cmake
freetype2\build\CMakeFiles\Export\lib\cmake\freetype\freetype-config-relwithdebinfo.cmake

And if I add the following to the freetype2\CMakeLists.txt:

  include(CMakePackageConfigHelpers)
  write_basic_package_version_file(
    ${CMAKE_INSTALL_LIBDIR}/cmake/freetype/freetype-config-version.cmake
    VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}
    COMPATIBILITY SameMajorVersion)

Then running cmake again generates the following file:

freetype2\build\lib\cmake\freetype\freetype-config-version.cmake

However, note that it is not located under CMakeFiles\Export\ like the other freetype-config-* files. Is this a problem?

Should I get rid of the ${CMAKE_INSTALL_LIBDIR}/ (which expands to lib), and simply generate it here:

freetype2\build\cmake\freetype\freetype-config-version.cmake

Or should I find a way to generate it in CMakeFiles\Export\lib\cmake\freetype? How?

Thank you!

[dalboris]

Just adding a link to this helpful resource, for anyone reading this thread and as confused as I was about *-config-version.cmake:

https://cliutils.gitlab.io/modern-cmake/chapters/install/installing.html

[JackBoosY]

@dalboris Just install it to ${CONFIG_INSTALL_PATH}, which is the same as other cmake files.

[dalboris]

@JackBoosY I can't find mention of ${CONFIG_INSTALL_PATH} in the cmake documentation or FreeType source. Did you mean something else? Also, by "install it to", do you mean that in addition to adding a write_basic_package_version_file(), I should also add a new install() command which copy the generated freetype-config-version.cmake from the build folder to another path?

Sorry for all these perhaps obvious questions, I'm new to all this.

[JackBoosY]

@dalboris Sorry for late, I completely forgot this issue.
In FREETYPE_SOURCE_PATH/CMakeLists.txt line 179:

# vcpkg config install path
option(CONFIG_INSTALL_PATH "location to install cmake config files" lib/cmake/freetype)

[dalboris]

Thanks @JackBoosY, this is useful, I'm now working on a FreeType patch. No worry about the delay, I was busy with other things anyway.

First notes:

1. It shouldn't be option(CONFIG_INSTALL_PATH ...) but set(CONFIG_INSTALL_PATH ... CACHE PATH ...), since it's not a boolean option.

2. Instead of lib/cmake/freetype, I'm planning to use ${CMAKE_INSTALL_LIBDIR}/cmake/freetype, since that's how the path is currently specified for the other CMake config files. ${CMAKE_INSTALL_LIBDIR} is defined by GNUInstallDirs and its value is either lib or lib64.

3. Since GNUInstallDirs is only included on line 473, I can't use ${CMAKE_INSTALL_LIBDIR} on line 179. So I'm planning to define CONFIG_INSTALL_PATH around line 530 (just before the install commands), instead of in line 179 (where the other options are defined).

[dalboris]

@JackBoosY Oh, I actually just realized that by:

# vcpkg config install path
option(CONFIG_INSTALL_PATH "location to install cmake config files" lib/cmake/freetype)

You were not saying "add this to the CMakeLists.txt". You were in fact referring to an already existing line that comes from vcpkg's ports/freetype/0002-Add-CONFIG_INSTALL_PATH-option.patch, see:

https://github.com/microsoft/vcpkg/pull/11846/files

This is confusing. Just to clarify, when I said "I'm working on a patch" in the last message, I meant I'm modifying the source CMakeLists.txt found in FreeType git's repository, and submitting the changes directly to FreeType folks. I wasn't taking about a ".patch" file in the vcpkg's port.

In fact, I do not quite understand the reason why #11846 introduced this CONFIG_INSTALL_PATH. Perhaps @kevinlul could clarify: was ${CMAKE_INSTALL_LIBDIR}/cmake/freetype not working as intended?

[dalboris]

OK, so I'm planning to submit to FreeType folks a change which modifies this:

  install(
    TARGETS freetype
      EXPORT freetype-targets
      LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
      ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
      RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
      FRAMEWORK DESTINATION Library/Frameworks
      COMPONENT libraries)
  install(
    EXPORT freetype-targets
      DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/freetype
      FILE freetype-config.cmake
      COMPONENT headers)

into this:

  include(CMakePackageConfigHelpers)
  write_basic_package_version_file(
    ${PROJECT_BINARY_DIR}/freetype-config-version.cmake
    VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}
    COMPATIBILITY SameMajorVersion)

  set(FT_CONFIG_INSTALL_PATH "${CMAKE_INSTALL_LIBDIR}/cmake/freetype" CACHE PATH
     "Specify where to install CMake config files")

  install(
    TARGETS freetype
      EXPORT freetype-targets
      LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
      ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
      RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
      FRAMEWORK DESTINATION Library/Frameworks
      COMPONENT libraries)
  install(
    EXPORT freetype-targets
      DESTINATION ${FT_CONFIG_INSTALL_PATH}
      FILE freetype-config.cmake
      COMPONENT headers)
  install(
    FILES ${PROJECT_BINARY_DIR}/freetype-config-version.cmake
    DESTINATION ${FT_CONFIG_INSTALL_PATH})

This successfuly creates a freetype-config-version.cmake file in the CMake build dir at config time, and copy it to <install_dir>/lib/cmake/freetype at install time.

Note that I'm using FT_CONFIG_INSTALL_PATH instead of CONFIG_INSTALL_PATH to avoid polluting the global namespace. But as I said, is this cache entry necessary at all? Would vcpkg (or anyone) ever like to set it to a different value than its default value of lib[64]/cmake/freetype?

[JackBoosY]

@dalboris Oh sorry, I didn't view the history before. After check that PR, I think we may not use CONFIG_INSTALL_PATH.
Right! That macro already removed by PR #12405.

[JackBoosY]

You need to install freetype-config-version.cmake into the same folder of other installed cmake, such as freetype-targets.cmake or freetype-config.cmake.

[dalboris]

@JackBoosY Perfect, indeed CONFIG_INSTALL_PATH seems already removed, so no need to re-add it. I've submitted a patch to the FreeType project: https://savannah.nongnu.org/bugs/index.php?58935 . It basically adds:

  include(CMakePackageConfigHelpers)
  write_basic_package_version_file(
    ${PROJECT_BINARY_DIR}/freetype-config-version.cmake
    VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}
    COMPATIBILITY SameMajorVersion)

  install(
    FILES ${PROJECT_BINARY_DIR}/freetype-config-version.cmake
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/freetype
    COMPONENT headers)

Let me know if you'd also like to apply this patch in the vcpkg port, while we wait for the patch to be merged upstream and a new version of FreeType to be released.

[JackBoosY]

@dalboris we need to wait for upstream merge that changes.

[dalboris]

@JackBoosY Thanks, waiting for upstream then. I've just sent them a reminder about this patch.

[dalboris]

Follow-up: the change is now merged upstream, so it should be available in the next version of FreeType.

See: https://git.savannah.gnu.org/cgit/freetype/freetype2.git/commit/?id=69353a19a197b0ab89b8382966c07f072fed8453