build.gradle

buildscript {
    dependencies {
        classpath (libs.licenseGradlePlugin) {
            exclude group: 'org.springframework', module: 'spring-core'
        }
    }

    configurations.configureEach {
        resolutionStrategy {
            force (libs.plexus.utils)
            force (libs.commons.compress)
        }
    }
}
plugins {
    alias (libs.plugins.sonarqube)
    id 'idea'
    alias(libs.plugins.spring.boot) apply false
}

repositories {
    mavenCentral()
}

idea {
    project {
        jdkName = '21'
        languageLevel = '21'
    }
    module {
        downloadSources = true
        excludeDirs -= layout.buildDirectory.get().asFile
        // FIXME: This might be wrong with the switch to WSDL2JAVA or even not needed
        buildDir.listFiles({ d, f -> f != 'generated-sources/wsimport' } as FilenameFilter).each { excludeDirs += it }
    }
}

wrapper {
    gradleVersion = '8.10'
}

ext {
    project_version='4.0.0'
}


subprojects {
    version = project_version

    tasks.withType(JavaCompile).configureEach {
        options.compilerArgs << "-Xlint:unchecked"
        options.compilerArgs << "-Xlint:deprecation"
        options.compilerArgs << "-Xlint:rawtypes"
        options.compilerArgs << "-Xlint:fallthrough"
        options.compilerArgs << "-Xlint:finally"
    }
}