build.gradle

plugins {
    id 'org.springframework.boot' version '2.3.0.RELEASE'
    id 'io.spring.dependency-management' version '1.0.9.RELEASE'
    id 'com.diffplug.gradle.spotless' version '4.1.0'
    id 'com.google.cloud.tools.jib' version '2.3.0' apply false
    id 'java'
    id 'application'
}

mainClassName = 'io.terrible.batch.Application'

jar {
    enabled = false
}

allprojects {
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'com.diffplug.gradle.spotless'
    apply plugin: 'java'

    group = 'io.terrible'
    version = '0.0.1-SNAPSHOT'
    sourceCompatibility = '1.8'

    repositories {
        mavenCentral()
    }

    dependencies {
        // Spring
        implementation 'org.springframework.boot:spring-boot-starter'

        // Apache
        implementation 'org.apache.commons:commons-lang3:3.10'
        implementation 'org.apache.commons:commons-math3:3.6.1'
        implementation 'commons-io:commons-io:2.6'

        // Google
        implementation 'com.google.guava:guava:29.0-jre'

        // Lombok
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        developmentOnly 'org.springframework.boot:spring-boot-devtools'
    }

    test {
        useJUnitPlatform()
    }

    spotless {
        java {
            licenseHeader '/* Licensed under Apache-2.0 */'
            importOrder 'java', 'javax', 'org', 'com', ''
            removeUnusedImports()
            googleJavaFormat()
        }
    }

    build.dependsOn spotlessJavaApply
}