build.gradle

import net.ltgt.gradle.errorprone.CheckSeverity

plugins {
    id 'java'
    id 'application'
    id 'net.ltgt.errorprone'        version '3.1.0'
    id 'com.github.spotbugs'        version '5.1.2'
    id 'nebula.release'             version '17.2.2'
}

group = 'com.pega.gcs'
description = "Pega-LogViewer"

apply from: "$rootDir/gradle/artifacts.gradle"
apply from: "$rootDir/gradle/jacoco.gradle"
apply from: "$rootDir/gradle/pmd.gradle"
apply from: "$rootDir/gradle/checkstyle.gradle"
apply from: "$rootDir/gradle/spotbugs.gradle"
apply from: "$rootDir/gradle/publishing.gradle"

repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://jitpack.io" }
}

dependencies {

    errorprone("com.google.errorprone:error_prone_core:2.21.1")

    implementation 'gnu.getopt:java-getopt:1.0.13'
    implementation 'org.jfree:jfreechart:1.5.4'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.15.2'
    implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-xml:2.15.2'
    implementation 'com.fasterxml.woodstox:woodstox-core:6.5.1'
    implementation 'org.codehaus.woodstox:stax2-api:4.2.1'
    implementation 'org.apache.poi:poi-ooxml:5.2.3'

    // Java 11 changes
    implementation 'jakarta.xml.bind:jakarta.xml.bind-api:4.0.0'
    implementation 'com.sun.xml.bind:jaxb-impl:4.0.3'
    
    implementation 'com.github.pegasystems:fringeutils-common:v3.4.6'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.0'
}

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

application {
    mainClassName = 'com.pega.gcs.logviewer.LogViewer'
    applicationDefaultJvmArgs = [
                                    '-Duser.dir=XXX_SET_USER_DIR_XXX',
                                    '-Dfile.encoding=UTF-8',
                                    '-Xms1G',
                                    '-Xmx4G',
                                    '-XX:+UseG1GC',
                                    '-XX:+UseStringDeduplication'
                                ]
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
    options.compilerArgs += ['-Xlint:-options']
    options.compilerArgs += ['-proc:none']
    // configure error prone
    options.errorprone.check("UnnecessaryParentheses", CheckSeverity.OFF)
}

tasks.withType(Javadoc) {
    failOnError = false
}

tasks.withType (Test) {
    maxParallelForks = 2

    testLogging {
        showStandardStreams = true
        events 'started', 'passed', 'failed'
    }

    jacoco {
        destinationFile = file("$buildDir/jacoco/${name}.exec")
        classDumpDir = file("$buildDir/jacoco/${name}_ClassDump")
    }
}

task copyLicense(type: Copy) {
    from "LICENSE"
    into "$buildDir"
}

// set user.dir to the distribution directory
startScripts {
    doLast {
        unixScript.text = unixScript.text.replace('XXX_SET_USER_DIR_XXX', "'\$APP_HOME'")
        windowsScript.text = windowsScript.text.replace('XXX_SET_USER_DIR_XXX', '%APP_HOME%')
    }
}

task copyPluginsDir(type: Copy) {

    if (project.hasProperty("buildGCS") ? Boolean.valueOf(buildGCS.trim()) : false ) {
        from "/src/main/resources/plugins"
        into "$buildDir/plugins"
        includeEmptyDirs = true
    }
}

applicationDistribution.from(copyPluginsDir) {
    into ('plugins')
}

build.finalizedBy jacocoTestReport, jacocoTestCoverageVerification