Grammar of recursive language

[ArtifyCZ]

Hello,
I'd like to ask how should I make working this grammar:

Program = _{ SOI ~ Expr* ~ EOI }

WHITESPACE = _{ " " | "\t" | NEWLINE }

Expr = { "(" ~ Term+ ~ ")" }

Term = ${ Expr | Number | String | Sequence | QuotedSymbol | Name }

Number = ${ HexNum | BinNum | FloatNum | DecNum }

HexNum = @{ "0x" ~ ASCII_HEX_DIGIT+ }
BinNum = @{ "0b" ~ ("0" | "1")+ }
FloatNum = @{ ("-"? ~ (ASCII_DIGIT+ ~ "." ~ ASCII_DIGIT*) | ("." ~ ASCII_DIGIT+)) }
DecNum = @{ "-"? ~ ASCII_DIGIT+ }

String = @{ QUOTATION_MARK ~ (("\\" ~ QUOTATION_MARK) | (!QUOTATION_MARK ~ ANY))* ~ QUOTATION_MARK }

Sequence = { "[" ~ Term* ~ "]" }

QuotedSymbol = ${ "'" ~ Name }

Name = @{ (!NameBannedChars ~ ANY)+ }
NameBannedChars = _{ WHITESPACE | QUOTATION_MARK | "(" | ")" | "[" | "]" }

It works for (println hello), (println 123), (foo bar baz), etc., but not for (println (+ 1 2)).

[ArtifyCZ]

Okay, I have found solution, whitespaces were the problem.

Program = _{ SOI ~ Expr* ~ EOI }

WHITESPACE = _{ " " | "\t" | NEWLINE }

COMMENT = _{ SingleLineComment | MultilineComment }
SingleLineComment = _{ "//" ~ (!NEWLINE ~ ANY)* ~ (NEWLINE | EOI) }
MultilineComment = _{ "/*" ~ (!"*/" ~ ANY)* ~ "*/" }

Expr = { "(" ~ Term+ ~ ")" }

Term = { Expr | Number | String | Sequence | Symbol }

Number = ${ HexNum | BinNum | FloatNum | DecNum }

HexNum = @{ "0x" ~ ASCII_HEX_DIGIT+ }
BinNum = @{ "0b" ~ ("0" | "1")+ }
FloatNum = @{ ("-"? ~ (ASCII_DIGIT+ ~ "." ~ ASCII_DIGIT*) | ("." ~ ASCII_DIGIT+)) }
DecNum = @{ "-"? ~ ASCII_DIGIT+ }

String = @{ QUOTATION_MARK ~ (("\\" ~ QUOTATION_MARK) | (!QUOTATION_MARK ~ ANY))* ~ QUOTATION_MARK }

Sequence = { "[" ~ Term* ~ "]" }

Symbol = @{ (!SymbolBannedChars ~ ANY)+ }
SymbolBannedChars = _{ WHITESPACE | QUOTATION_MARK | "(" | ")" | "[" | "]" }