BUILD.arrow

# Description:
#   Apache Arrow library

package(default_visibility = ["//visibility:public"])

licenses(["notice"])  # Apache 2.0

exports_files(["LICENSE.txt"])

load("@com_github_google_flatbuffers//:build_defs.bzl", "flatbuffer_cc_library")
load("@com_github_grpc_grpc//bazel:grpc_build_system.bzl", "grpc_proto_library")

flatbuffer_cc_library(
  name = "arrow_format",
  srcs = [
    "cpp/src/arrow/ipc/feather.fbs",
    "format/File.fbs",
    "format/Message.fbs",
    "format/Schema.fbs",
    "format/SparseTensor.fbs",
    "format/Tensor.fbs",
  ],
  flatc_args = [
    "--scoped-enums",
    "--gen-object-api",
  ],
  out_prefix = "cpp/src/generated/",
)

grpc_proto_library(
  name = "flight_proto",
  srcs = ["cpp/src/arrow/flight/Flight.proto"],
)

grpc_proto_library(
  name = "flight_perf_proto",
  srcs = ["cpp/src/arrow/flight/perf.proto"],
)

genrule(
  name = "arrow_util_config",
  srcs = ["cpp/src/arrow/util/config.h.cmake"],
  outs = ["cpp/src/arrow/util/config.h"],
  cmd = (
    "sed " +
    "-e 's/@ARROW_VERSION_MAJOR@/3/g' " +
    "-e 's/@ARROW_VERSION_MINOR@/0/g' " +
    "-e 's/@ARROW_VERSION_PATCH@/0/g' " +
    "-e 's/cmakedefine ARROW_USE_NATIVE_INT128/undef ARROW_USE_NATIVE_INT128/g' " +
    "-e 's/cmakedefine/define/g' " +
    "$< >$@"),
)

genrule(
  name = "parquet_version_h",
  srcs = ["cpp/src/parquet/parquet_version.h.in"],
  outs = ["cpp/src/parquet/parquet_version.h"],
  cmd = (
    "sed " +
    "-e 's/@PARQUET_VERSION_MAJOR@/1/g' " +
    "-e 's/@PARQUET_VERSION_MINOR@/5/g' " +
    "-e 's/@PARQUET_VERSION_PATCH@/1/g' " +
    "$< >$@"),
)

cc_library(
  name = "arrow",
  srcs = glob([
      "cpp/src/arrow/*.cc",
      "cpp/src/arrow/array/*.cc",
      "cpp/src/arrow/csv/*.cc",
      "cpp/src/arrow/io/*.cc",
      "cpp/src/arrow/ipc/*.cc",
      "cpp/src/arrow/json/*.cc",
      "cpp/src/arrow/tensor/*.cc",
      "cpp/src/arrow/util/*.cc",
      "cpp/src/arrow/flight/*.cc",
      # "cpp/src/arrow/python/*.cc",

      "cpp/src/arrow/filesystem/util_internal.cc",
      "cpp/src/arrow/filesystem/localfs.cc",
      "cpp/src/arrow/filesystem/filesystem.cc",
      "cpp/src/arrow/filesystem/mockfs.cc",
      "cpp/src/arrow/filesystem/path_util.cc",
      "cpp/src/arrow/compute/cast.cc",
      "cpp/src/arrow/compute/exec.cc",
      "cpp/src/arrow/compute/kernel.cc",
      "cpp/src/arrow/compute/function.cc",
      "cpp/src/arrow/compute/registry.cc",
      "cpp/src/arrow/compute/kernels/scalar_*.cc",
      "cpp/src/arrow/compute/api_*.cc",
      "cpp/src/arrow/compute/kernels/codegen_*.cc",
      "cpp/src/arrow/compute/kernels/vector_*.cc",
      "cpp/src/arrow/compute/kernels/util_*.cc",
      "cpp/src/arrow/compute/kernels/aggregate_*.cc",
      "cpp/src/arrow/compute/kernels/hash_*.cc",
      "cpp/src/arrow/vendored/musl/strptime.c",
      "cpp/src/arrow/vendored/optional.hpp",
      "cpp/src/arrow/vendored/base64.cpp",
      "cpp/src/arrow/vendored/base64.h",
      "cpp/src/arrow/vendored/string_view.hpp",
      "cpp/src/arrow/vendored/variant.hpp",
      "cpp/src/arrow/vendored/uriparser/*.c",
      "cpp/src/arrow/**/*.h",
      "cpp/src/parquet/**/*.h",
      "cpp/src/parquet/**/*.cc",
      "cpp/src/generated/*.h",
      "cpp/src/generated/*.cpp",

    ],
    exclude = [
      "cpp/src/**/*_benchmark.cc",
      "cpp/src/arrow/flight/perf_server.cc",
      "cpp/src/**/*_main.cc",
      "cpp/src/**/*_nossl.cc",
      "cpp/src/**/*_test.cc",
      "cpp/src/**/test_*.cc",
      "cpp/src/**/*hdfs*.cc",
      "cpp/src/**/*fuzz*.cc",
      "cpp/src/**/file_to_stream.cc",
      "cpp/src/**/stream_to_file.cc",
      "cpp/src/arrow/util/bpacking_avx2.cc",
      "cpp/src/arrow/util/bpacking_avx512.cc",
    ],),

  hdrs = [
    # declare header from above genrule
    "cpp/src/arrow/util/config.h",
    "cpp/src/parquet/parquet_version.h",
    "cpp/src/arrow/filesystem/localfs.h",
    "cpp/src/arrow/filesystem/filesystem.h",
    "cpp/src/arrow/flight/server.h",
    # "cpp/src/arrow/python/pyarrow.h",
  ],
  copts = [],
  defines = [
    "ARROW_WITH_BROTLI",
    "ARROW_WITH_SNAPPY",
    "ARROW_WITH_LZ4",
    "ARROW_WITH_ZLIB",
    "ARROW_WITH_ZSTD",
    "ARROW_WITH_BZ2",
    "ARROW_STATIC",
    "ARROW_EXPORT=",
    "PARQUET_STATIC",
    "PARQUET_EXPORT=",
    "WIN32_LEAN_AND_MEAN",
  ],
  includes = [
    "cpp/src",
    "cpp/src/arrow/vendored/xxhash",
  ],
  textual_hdrs = [
    "cpp/src/arrow/vendored/xxhash/xxhash.c",
  ],
  deps = [
    ":arrow_format",
    ":flight_proto",
    ":flight_perf_proto",
    "@openssl",
    "@boost//:multiprecision",
    "@boost//:random",
    "@boost//:asio",
    "@boost//:filesystem",
    "@boost//:program_options",
    "@brotli",
    "@bzip2",
    "@double-conversion",
    "@lz4",
    "@rapidjson",
    "@snappy",
    "@thrift",
    "@xsimd",
    "@zlib",
    #"@zstd",
    "@com_github_facebook_zstd//:zstd",
    "@io_opentelemetry_cpp//api",
    "@io_opentelemetry_cpp//exporters/ostream:ostream_span_exporter",
    # "@io_opentelemetry_cpp//exporters/otlp:otlp_http_exporter",
    "@io_opentelemetry_cpp//sdk/src/trace",
    # "@liborc//:liborc",
    # "@com_google_protobuf//:protobuf",
    "@com_github_grpc_grpc//:grpc++",
    "@com_github_gflags_gflags//:gflags",
    # "@pybind11",
  ],
)