build.gradle

buildscript {
    ext.kotlin_version = '1.5.0'
    repositories {
        google()
        mavenCentral()
        maven {
            url "https://plugins.gradle.org/m2/"
        }

    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.1.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.jlleitschuh.gradle:ktlint-gradle:11.5.1"
    }
}

repositories {
    google()
    mavenCentral()
}

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'
apply plugin: 'maven-publish'
apply plugin: "org.jlleitschuh.gradle.ktlint"

android {
    compileSdkVersion 30
    buildToolsVersion "30.0.3"

    defaultConfig {
        minSdkVersion 19
        targetSdkVersion 30
        versionCode 1
        versionName project.getProperty('libraryVersion')

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
    }

    buildTypes {
        debug {
            buildConfigField("String", "VERSION_NAME", "\"${defaultConfig.versionName}\"")
            debuggable true
        }
        release {
            buildConfigField("String", "VERSION_NAME", "\"${defaultConfig.versionName}\"")
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    testOptions {
        kotlinOptions {
            freeCompilerArgs += [
                    '-Xopt-in=kotlin.RequiresOptIn',
            ]
        }
    }
}

ktlint {
    version = "0.50.0"
    verbose = true
}

task sourceJar(type: Jar) {
    from android.sourceSets.main.java.srcDirs
    classifier "sources"
}

task testLogging(type: Test) {
    testLogging {
        events "passed", "skipped", "failed"
    }
}

task copyLibs(type: Copy) {
    from configurations.compile
    into 'libs'
}

dependencies {
    implementation fileTree(dir: "libs", include: ["*.jar"])
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    implementation 'androidx.core:core-ktx:1.5.0'
    implementation 'androidx.appcompat:appcompat:1.2.0'

    implementation 'com.google.code.gson:gson:2.8.9'
    implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-android:1.5.0'

    testImplementation 'junit:junit:4.12'
    testImplementation 'org.jetbrains.kotlinx:kotlinx-coroutines-test:1.5.0'
    testImplementation "io.mockk:mockk:1.12.0"
    testImplementation 'com.github.tomakehurst:wiremock:2.27.2'
    testImplementation "org.slf4j:slf4j-simple:1.8.0-beta4"
    testImplementation 'com.squareup.okhttp3:mockwebserver:4.9.0'
}

artifacts {
    archives sourceJar
}

afterEvaluate {
    publishing {
        publications {
            release(MavenPublication) {
                from components.release

                groupId 'com.statsig'
                artifactId 'android-sdk'
                version project.getProperty('libraryVersion')
                pom {
                    name = "Statsig Android SDK"
                    description = "A SDK for integrating Statsig with Android Apps"
                    url = "https://github.com/statsig-io/android-sdk"
                    organization {
                        name = "Statsig"
                        url = "https://www.statsig.com"
                    }
                    licenses {
                        license {
                            name = "Apache License, Version 2.0"
                            url = "https://www.apache.org/licenses/LICENSE-2.0.txt"
                            distribution = "repo"
                        }
                    }
                    developers {
                        developer {
                            id = "tore"
                            name = "Tore Hanssen"
                            email = "tore@statsig.com"
                        }
                    }
                }
            }
        }
        repositories {
            maven {
                url "$buildDir/repo"
            }
        }
    }
}