build.gradle

plugins {
    id 'java-library'
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.moddev' version '1.0.14'
}

tasks.named('wrapper', Wrapper).configure {
    distributionType = Wrapper.DistributionType.BIN
}

abstract class TeaConDumpPathToGitHub extends DefaultTask {
    @Input
    abstract Property<String> getPublishName()
    @InputFile
    abstract RegularFileProperty getTargetFile()
    @TaskAction
    void dump() {
        if (System.env.GITHUB_ACTIONS) {
            File theFile = targetFile.getAsFile().get()

            def outputFile = new File(System.env.GITHUB_OUTPUT)
            // Use the env-specific line separator for maximally possible compatibility
            def newLine = System.getProperty('line.separator')

            // Write out new env variable for later usage
            outputFile << newLine << "artifact_name=${theFile.getName()}"
            outputFile << newLine << "artifact_publish_name=${publishName.get()}"
            outputFile << newLine << "artifact_path=${theFile.absolutePath}"
        }
    }
}

version = mod_version
group = 'org.teacon'

repositories {
    mavenLocal()
    mavenCentral()
    maven {
        name = 'BlueMap'
        url = 'https://repo.bluecolored.de/releases'
    }
}

base {
    archivesName = 'AreaControl-NeoForge-1.21'
}

// Mojang ships Java 21 to end users starting in 1.20.5, so mods should target Java 21.
java.toolchain.languageVersion = JavaLanguageVersion.of(21)

neoForge {
    // Specify the version of NeoForge to use.
    version = project.neo_version

    parchment {
        mappingsVersion = project.parchment_mappings_version
        minecraftVersion = project.parchment_minecraft_version
    }

    runs {
        client {
            client()
        }

        server {
            server()
            programArgument '--nogui'
        }

        // applies to all the run configs above
        configureEach {
            logLevel = org.slf4j.event.Level.DEBUG
        }
    }

    mods {
        // define mod <-> source bindings
        // these are used to tell the game which sources are for which mod
        // mostly optional in a single mod project
        // but multi mod projects should define one per mod
        area_control {
            sourceSet(sourceSets.main)
        }
    }

    unitTest {
        enable()
        testedMod = mods.area_control
    }
}

dependencies {
    // Yes you see this right, LuckPerms.
    // This is for our custom ContextCalculator support.
    compileOnly 'net.luckperms:api:5.4'
    compileOnly 'de.bluecolored.bluemap:BlueMapAPI:2.7.2'

    testImplementation platform('org.junit:junit-bom:5.10.3')
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testImplementation 'org.mockito:mockito-core:5.11.0'
    testImplementation 'org.mockito:mockito-junit-jupiter:5.12.0'
    testImplementation 'com.google.jimfs:jimfs:1.3.0'
}

test {
    useJUnitPlatform()
}

// This block of code expands all declared replace properties in the specified resource targets.
// A missing property will result in an error. Properties are expanded using ${} Groovy notation.
// When "copyIdeResources" is enabled, this will also run before the game launches in IDE environments.
// See https://docs.gradle.org/current/dsl/org.gradle.language.jvm.tasks.ProcessResources.html
tasks.withType(ProcessResources).configureEach {
    var replaceProperties = [
            minecraft_version      : minecraft_version,
            minecraft_version_range: minecraft_version_range,
            neo_version            : neo_version,
            neo_version_range      : neo_version_range,
            loader_version_range   : loader_version_range,
            mod_id                 : mod_id,
            mod_name               : mod_name,
            mod_license            : mod_license,
            mod_version            : mod_version,
            mod_authors            : mod_authors,
            mod_description        : mod_description
    ]
    inputs.properties replaceProperties

    filesMatching(['META-INF/neoforge.mods.toml']) {
        expand replaceProperties
    }
}

publishing {
    publications {
        release(MavenPublication) {
            groupId = "org.teacon"
            artifactId = "AreaControl-NeoForge-1.21"

            artifact jar
            pom {
                name = 'AreaControl for Minecraft 1.21'
                description = 'Comprehensive (eventually) plot management mod'
                url = 'https://github.com/teaconmc/XKDeco'
                issueManagement {
                    system = 'GitHub Issues'
                    url = 'https://github.com/teaconmc/XKDeco/issues'
                }
                scm {
                    url = 'https://github.com/teaconmc/XKDeco'
                    connection = 'scm:git:git://github.com/teaconmc/XKDeco.git'
                    developerConnection = 'scm:git:git@github.com:teaconmc/XKDeco.git'
                }
            }
        }
    }
    repositories {
        maven {
            name = "teacon"
            url = "s3://maven/"
            credentials(AwsCredentials) {
                accessKey = System.env.ARCHIVE_ACCESS_KEY
                secretKey = System.env.ARCHIVE_SECRET_KEY
            }
        }
    }
}

tasks.withType(PublishToMavenRepository) {
    onlyIf {
        System.env.ARCHIVE_ACCESS_KEY && System.env.ARCHIVE_SECRET_KEY
    }
}

tasks.register("githubActionOutput", TeaConDumpPathToGitHub) { task ->
    task.onlyIf {
        System.env.GITHUB_ACTIONS
    }
    task.getPublishName().set("${jar.archiveBaseName.get()}-${version}.jar")
    task.getTargetFile().set(jar.archiveFile)
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

// IDEA no longer automatically downloads sources/javadoc jars for dependencies, so we need to explicitly enable the behavior.
idea {
    module {
        downloadSources = true
        downloadJavadoc = true
    }
}