build.gradle

// DroidMate, an automated execution generator for Android apps.
// Copyright (C) 2012-2018. Saarland University
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program.  If not, see <http://www.gnu.org/licenses/>.
//
// Current Maintainers:
// Nataniel Borges Jr. <nataniel dot borges at cispa dot saarland>
// Jenny Hotzkow <jenny dot hotzkow at cispa dot saarland>
//
// Former Maintainers:
// Konrad Jamrozik <jamrozik at st dot cs dot uni-saarland dot de>
//
// web: www.droidmate.org
plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.3.50'
    id 'maven-publish'
    id 'application'
    id 'java'
    id 'maven'
	id 'com.github.johnrengelman.shadow' version '5.2.0'
}

group 'org.droidmate'
version '1.4.2-SNAPSHOT'

apply from: file("${rootProject.projectDir}/ktlint.gradle")

repositories {
    maven { url = "https://soot-build.cs.upb.de/nexus/repository/soot-release/" }
    maven { url = "https://soot-build.cs.upb.de/nexus/repository/soot-snapshot/" }
    mavenCentral()
    maven { url = 'https://jitpack.io' }
}

task sourcesJar(type: Jar, dependsOn: "classes") {
    classifier = 'sources'
    from sourceSets.main.allJava
    from sourceSets.main.allSource
    from sourceSets.test.allSource
}

artifacts {
    archives sourcesJar
}

mainClassName = "org.droidmate.coverage.Instrumenter"

jar {
    manifest {
        attributes 'Main-Class': "org.droidmate.coverage.Instrumenter"
    }
}

dependencies {
    testImplementation 'junit:junit:4.12'

    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"

    //compile group:'org.droidmate', name: 'common', version: "1.3.2-RC0"
    implementation 'com.github.uds-se:droidmate-common:1.4.2-SNAPSHOT'

    implementation 'org.json:json:20160212'
    implementation group: 'com.google.guava', name: 'guava', version: '26.0-jre'
    implementation group: 'com.ximpleware', name: 'vtd-xml', version: '2.13.4'
    implementation 'org.apache.commons:commons-lang3:3.8'

    implementation 'com.natpryce:konfig:1.6.6.0'  // configuration library
    
    implementation("ca.mcgill.sable:soot:3.3.0") {
        exclude group: 'de.upb.cs.swt', module: 'heros'
    }
    implementation ("de.tud.sse:soot-infoflow-android:2.7.1") {
        // FlowDroid uses an older version of Soot, let's use the newest one!
        exclude group: 'ca.mcgill.sable', module: 'soot'
    }
    implementation "de.upb.cs.swt:heros:1.1.0"
}

test {
    maxHeapSize = "2048m"
    testLogging {
        events "failed"
        exceptionFormat "full"
    }

}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/uds-se/droidmate-coverage")
            credentials {
                username = System.getenv("GITHUB_USERNAME")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }
    publications {
        gpr(MavenPublication) {
            from(components.java)
        }
    }
}