build.gradle

/*
 * Copyright (c) 2017 Dell Inc., or its subsidiaries. All Rights Reserved.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *   http://www.apache.org/licenses/LICENSE-2.0
 *
 */

group "io.pravega.anomalydetection"
version projectVersion

apply plugin: "java"
apply plugin: 'application'
apply plugin: 'com.github.johnrengelman.shadow'

mainClassName = 'io.pravega.anomalydetection.ApplicationMain'
applicationDefaultJvmArgs = ["-Dlog4j.configuration=file:conf/log4j.properties"]

configurations {
    shadowRelocate {
    }
}

dependencies {
    compileOnly "org.slf4j:slf4j-log4j12:1.7.14"
    compile "io.pravega:pravega-connectors-flink_2.11:${pravegaConnectorsVersion}"
    compileOnly "org.apache.flink:flink-streaming-java_2.11:${flinkVersion}"
    compileOnly "org.apache.flink:flink-connector-elasticsearch5_2.11:${flinkVersion}"
    shadowRelocate "org.apache.flink:flink-connector-elasticsearch5_2.11:${flinkVersion}"
    if (includeNautilusCredentials.toBoolean()) {
        shadowRelocate "com.emc.nautilus:pravega-credentials:${nautilusCredentials}"
    }
}

shadowJar {

    configurations = [project.configurations.runtime, project.configurations.shadowRelocate]

    relocate "org.slf4j", "es.shaded.org.slf4j"
    relocate "com.google.code.findbugs", "es.shaded.com.google.code.findbugs"
    relocate "net.sf.jopt-simple", "es.shaded.net.sf.jopt-simple"
    relocate "com.carrotsearch", "es.shaded.com.carrotsearch"
    relocate "joda-time", "es.shaded.joda-time"
    relocate "org.yaml", "es.shaded.org.yaml"
    relocate "com.fasterxml", "es.shaded.com.fasterxml"
    relocate "com.tdunning", "es.shaded.com.tdunning"
    relocate "org.hdrhistogram", "es.shaded.org.hdrhistogram"
    relocate "net.java.dev.jna", "es.shaded.net.java.dev.jna"
    relocate "io.netty", "es.shaded.io.netty"
    relocate "org.apache.httpcomponents", "es.shaded.org.apache.httpcomponents"
    relocate "commons-codec", "es.shaded.commons-codec"
    relocate "commons-logging", "es.shaded.commons-logging"
    relocate "com.github", "es.shaded.com.github"
    relocate "org.apache.logging.log4j", "es.shaded.org.apache.logging.log4j"

    mergeServiceFiles()
}

distributions {
    main {
        contents {
            into('lib') {
                from shadowJar
                from(project.configurations.shadow)
            }
        }
    }
}

run {
    standardInput = System.in

    if (project.hasProperty("argsList")) {
        args(argsList.split(' '))
    }

}