settings.gradle

// Copyright (C) 2014-2016 LinkedIn Corp. All rights reserved.
//
// Licensed under the Apache License, Version 2.0 (the "License"); you may not use
// this file except in compliance with the License. You may obtain a copy of the
// License at  http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software distributed
// under the License is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR
// CONDITIONS OF ANY KIND, either express or implied.

apply from: 'gradle/scripts/hadoop-version.gradle'

def modules = ['gobblin-admin',
               'gobblin-api',
               'gobblin-azkaban',
               'gobblin-compaction',
               'gobblin-config-management',
               'gobblin-core',
               'gobblin-core-base',
               'gobblin-distribution',
               'gobblin-example',
               'gobblin-hive-registration',
               'gobblin-metrics',
               'gobblin-metastore',
               'gobblin-rest-service',
               'gobblin-runtime',
               'gobblin-runtime-hadoop',
               'gobblin-utility',
               'gobblin-salesforce',
               'gobblin-test-harness',
               'gobblin-tunnel',
               'gobblin-data-management',
               'gobblin-config-management',
               'gobblin-audit',
               'gobblin-yarn',
               'gobblin-cluster',
               'gobblin-aws',
               'gobblin-modules',
               'gobblin-test-utils']

// Disable jacoco for now as Kafka 0.8 is the default version and jacoco does not like the same classes 
// being declared in different modules
def jacocoBlacklist =  new HashSet([
    "gobblin-modules:gobblin-kafka-09"
])

modules.each { module ->
  include "${module}"
  file(module).eachDir { submodule ->
    if (!submodule.name.startsWith('.') && !submodule.name.equals('src')) {
        def submoduleId = "${module}:${submodule.name}"
        if (System.getProperty('jacocoBuild') == null || !jacocoBlacklist.contains(submoduleId.toString())) {
            include submoduleId 
        }
        else {
            println "Ignoring blacklisted module ${submoduleId}"
        }
    }
  }
}