Add ament{_cmake,}_yamllint packages

ament_cmake_yamllint/CMakeLists.txt

@@ -0,0 +1,24 @@
+cmake_minimum_required(VERSION 3.5)
+
+project(ament_cmake_yamllint NONE)
+
+find_package(ament_cmake_core REQUIRED)
+find_package(ament_cmake_test REQUIRED)
+
+ament_package()
+
+install(
+  DIRECTORY cmake
+  DESTINATION share/${PROJECT_NAME}
+)
+
+if(BUILD_TESTING)
+  find_package(ament_cmake_copyright REQUIRED)
+  ament_copyright()
+
+  find_package(ament_cmake_lint_cmake REQUIRED)
+  ament_lint_cmake()
+
+  find_package(ament_cmake_xmllint REQUIRED)
+  ament_xmllint()
+endif()

ament_cmake_yamllint/cmake/ament_yamllint.cmake

@@ -0,0 +1,69 @@
+# Copyright 2014-2018 Open Source Robotics Foundation, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+#
+# Add a test to check YAML files with yamllint.
+#
+# :param TESTNAME: the name of the test, default: "yamllint"
+# :type TESTNAME: string
+# :param ARGN: the files or directories to check
+# :type ARGN: list of strings
+#
+# @public
+#
+function(ament_yamllint)
+  cmake_parse_arguments(ARG "" "MAX_LINE_LENGTH;TESTNAME" "" ${ARGN})
+  if(NOT ARG_TESTNAME)
+    set(ARG_TESTNAME "yamllint")
+  endif()
+
+  find_program(ament_yamllint_BIN NAMES "ament_yamllint")
+  if(NOT ament_yamllint_BIN)
+    message(FATAL_ERROR "ament_yamllint() could not find program 'ament_yamllint'")
+  endif()
+
+  set(result_file "${AMENT_TEST_RESULTS_DIR}/${PROJECT_NAME}/${ARG_TESTNAME}.xunit.xml")
+  set(cmd "${ament_yamllint_BIN}" "--xunit-file" "${result_file}")
+  list(APPEND cmd ${ARG_UNPARSED_ARGUMENTS})
+
+  find_program(yamllint_BIN NAMES "yamllint")
+
+  if(NOT yamllint_BIN)
+    if(${CMAKE_VERSION} VERSION_LESS "3.8.0")
+      message(WARNING "WARNING: 'yamllint' not found, skipping yamllint test creation")
+      return()
+    endif()
+  endif()
+
+  file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/ament_yamllint")
+  ament_add_test(
+    "${ARG_TESTNAME}"
+    COMMAND ${cmd}
+    OUTPUT_FILE "${CMAKE_BINARY_DIR}/ament_yamllint/${ARG_TESTNAME}.txt"
+    RESULT_FILE "${result_file}"
+    WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
+  )
+  set_tests_properties(
+    "${ARG_TESTNAME}"
+    PROPERTIES
+    LABELS "yamllint;linter"
+  )
+  if(NOT yamllint_BIN)
+    set_tests_properties(
+      "${ARG_TESTNAME}"
+      PROPERTIES
+      DISABLED TRUE
+    )
+  endif()
+endfunction()

ament_cmake_yamllint/doc/index.rst

@@ -0,0 +1,37 @@
+ament_yamllint
+==============
+
+Checks YAML files using `yamllint <https://yamllint.readthedocs.io>`_.
+Files with the following extensions are being considered: ``.yaml``, ``.yml``.
+
+
+How to run the check from the command line?
+-------------------------------------------
+
+The command line tool is provided by the package `ament_yamllint
+<https://github.com/ament/ament_lint>`_.
+
+
+How to run the check from within a CMake ament package as part of the tests?
+----------------------------------------------------------------------------
+
+``package.xml``:
+
+.. code:: xml
+
+    <buildtool_depend>ament_cmake</buildtool_depend>
+    <test_depend>ament_cmake_yamllint</test_depend>
+
+``CMakeLists.txt``:
+
+.. code:: cmake
+
+    find_package(ament_cmake REQUIRED)
+    if(BUILD_TESTING)
+      find_package(ament_cmake_yamllint REQUIRED)
+      ament_yamllint()
+    endif()
+
+The documentation of the package `ament_cmake_test
+<https://github.com/ament/ament_cmake>`_ provides more information on testing
+in CMake ament packages.

ament_cmake_yamllint/package.xml

@@ -0,0 +1,30 @@
+<?xml version="1.0"?>
+<?xml-model href="http://download.ros.org/schema/package_format2.xsd" schematypens="http://www.w3.org/2001/XMLSchema"?>
+<package format="2">
+  <name>ament_cmake_yamllint</name>
+  <version>0.11.3</version>
+  <description>
+    The CMake API for ament_yamllint to check YAML file using yamllint.
+  </description>
+
+  <maintainer email="[email protected]">Michael Jeronimo</maintainer>
+  <maintainer email="[email protected]">Michel Hidalgo</maintainer>
+
+  <license>Apache License 2.0</license>
+
+  <author email="[email protected]">Scott K Logan</author>
+
+  <buildtool_depend>ament_cmake_core</buildtool_depend>
+  <buildtool_depend>ament_cmake_test</buildtool_depend>
+
+  <buildtool_export_depend>ament_cmake_test</buildtool_export_depend>
+  <buildtool_export_depend>ament_yamllint</buildtool_export_depend>
+
+  <test_depend>ament_cmake_copyright</test_depend>
+  <test_depend>ament_cmake_lint_cmake</test_depend>
+  <test_depend>ament_cmake_xmllint</test_depend>
+
+  <export>
+    <build_type>ament_cmake</build_type>
+  </export>
+</package>

ament_yamllint/ament_yamllint/configuration/yamllint.yaml

@@ -0,0 +1,9 @@
+---
+extends: default
+
+rules:
+  document-start: disable
+  indentation:
+    indent-sequences: consistent
+  line-length: disable
+  new-lines: disable