Merge pull request #1490 from professional-ian/professional-ian-event…

…bridge-schedule-to-eventbridge-terraform

Thanks for the contribution

eventbridge-schedule-to-eventbridge-terraform/README.md

@@ -0,0 +1,53 @@
+# Amazon EventBridge Scheduler to Amazon EventBridge
+
+This pattern will create an [EventBridge Scheduler](https://docs.aws.amazon.com/scheduler/latest/UserGuide/getting-started.html) to publish an event to EventBridge every minute using templated targets. The pattern is deployed using Terraform to create the EventBridge Scheduler, EventBridge bus and rules as well as the IAM resources required for Scheduler to interact with EventBridge and CloudWatch. 
+
+Learn more about this pattern at Serverless Land Patterns: https://serverlessland.com/patterns/eventbridge-schedule-to-eventbridge-terraform.
+
+Important: this application uses various AWS services and there are costs associated with these services after the Free Tier usage - please see the [AWS Pricing page](https://aws.amazon.com/pricing/) for details. You are responsible for any AWS costs incurred. No warranty is implied in this example.
+
+## Requirements
+
+* [Create an AWS account](https://portal.aws.amazon.com/gp/aws/developer/registration/index.html) if you do not already have one and log in. The IAM user that you use must have sufficient permissions to make necessary AWS service calls and manage AWS resources.
+* [AWS CLI](https://docs.aws.amazon.com/cli/latest/userguide/install-cliv2.html) installed and configured
+* [Git Installed](https://git-scm.com/book/en/v2/Getting-Started-Installing-Git)
+* [Terraform](https://learn.hashicorp.com/tutorials/terraform/install-cli?in=terraform/aws-get-started) installed
+
+## Deployment Instructions
+
+1. Create a new directory, navigate to that directory in a terminal and clone the GitHub repository:
+    ``` 
+    git clone https://github.com/aws-samples/serverless-patterns
+    ```
+1. Change directory to the pattern directory:
+    ```
+    cd eventbridge-schedule-to-eventbridge-terraform
+    ```
+1. From the command line, initialize Terraform:
+    ```
+    terraform init
+    ```
+1. From the commend line, apply the configuration in the main.tf file and follow the prompts:
+    ```
+    terraform apply
+    ```
+
+## How it works
+
+An Amazon EventBridge Schedule is used to publish an EventBridge event using templated targets. The Terraform stack creates an EventBridge Schedule to invoke the PutEvents operation in EventBridge to publish an event to a custom event bus. The event is then matched to an EventBridge rule, with a CloudWatch Log Group set as the rule's target. 
+
+## Testing
+
+1. After deployment, view the schedule created in the Amazon EventBridge console under Scheduler>Schedules. 
+2. From the Amazon EventBridge console, navigate to the Rules dashboard and select the "scheduler-event-bus" to view the Rule. From the Targets menu on the "schedule-rule", navigate to the CloudWatch log group configured as the target to the rule. A Log stream is created each minute, you can view the payload passed by Scheduler in the event details. 
+
+## Cleanup
+
+1. Delete all created resources and follow prompts:
+    ```
+    terraform destroy
+    ```
+----
+Copyright 2023 Amazon.com, Inc. or its affiliates. All Rights Reserved.
+
+SPDX-License-Identifier: MIT-0

eventbridge-schedule-to-eventbridge-terraform/example-pattern.json

@@ -0,0 +1,58 @@
+{
+    "title": "Amazon EventBridge Scheduler to Amazon Eventbridge",
+    "description": "Use EventBridge Scheduler to send custom events to EventBridge on a schedule",
+    "language": "",
+    "level": "300",
+    "framework": "Terraform",
+    "introBox": {
+      "headline": "How it works",
+      "text": [
+        "This sample project demonstrates how to use Amazon EventBridge Scheduler to send custom events to Amazon EventBridge on a schedule. This pattern leverages templated targets with EventBridge Scheduler to talk directly to EventBridge using the PutEvents API operation.",
+        "The pattern is deployed using Terraform to create the EventBridge Scheduler, EventBridge bus and rules as well as the IAM resources required for Scheduler to interact with EventBridge and CloudWatch."
+      ]
+    },
+    "gitHub": {
+      "template": {
+        "repoURL": "https://github.com/aws-samples/serverless-patterns/tree/main/eventbridge-schedule-to-eventbridge-terraform",
+        "templateURL": "serverless-patterns/eventbridge-schedule-to-eventbridge-terraform",
+        "projectFolder": "eventbridge-schedule-to-eventbridge-terraform",
+        "templateFile": "eventbridge-schedule-to-eventbridge-terraform/main.tf"
+      }
+    },
+    "resources": {
+      "bullets": [
+        {
+          "text": "Amazon EventBridge Scheduler",
+          "link": "https://docs.aws.amazon.com/eventbridge/latest/userguide/scheduler.html"
+        },
+        {
+          "text": "Send custom events to Amazon Eventbridge",
+          "link": "https://docs.aws.amazon.com/eventbridge/latest/APIReference/API_PutEvents.html"
+        }
+      ]
+    },
+    "deploy": {
+      "text": [
+        "terraform apply"
+      ]
+    },
+    "testing": {
+      "text": [
+        "See the Github repo for detailed testing instructions."
+      ]
+    },
+    "cleanup": {
+      "text": [
+        "Delete the stack: <code>terraform destroy</code>."
+      ]
+    },
+    "authors": [
+      {
+        "name": "Ian Lodge",
+        "image": "https://avatars.githubusercontent.com/u/135351711?v=4",
+        "bio": "Ian is a Solutions Architect at Amazon Web Services based in the US.",
+        "linkedin": "https://www.linkedin.com/in/ian-lodge"
+      }
+    ]
+  }
+

eventbridge-schedule-to-eventbridge-terraform/main.tf

@@ -0,0 +1,178 @@
+# This template uses publishes an EventBridge event every minute using Amazon EventBridge Scheduler.
+
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = ">= 4.64.0"
+    }
+  }
+
+  required_version = ">= 0.14.9"
+}
+
+provider "aws" {
+  profile = "default"
+  region  = "us-east-1"
+}
+
+
+# Create custom event bus
+
+resource "aws_cloudwatch_event_bus" "scheduler-custom-event-bus" {
+    name = "scheduler-event-bus"
+}
+
+#Configuring dead-letter queues: https://docs.aws.amazon.com/scheduler/latest/UserGuide/configuring-schedule-dlq.html
+# Use cmd for troubleshooting "aws sqs get-queue-attributes --queue-url your-dlq-url --attribute-names QueueArn"
+
+resource "aws_sqs_queue" "scheduler-dlq" {
+    name = "scheduler-dlq"
+}
+
+# This section configures an EventBridge Rule that uses a CloudWatch Log Group as a target
+
+resource "aws_cloudwatch_event_rule" "rule" {
+    name = "schedule-rule"
+    event_bus_name = aws_cloudwatch_event_bus.scheduler-custom-event-bus.name
+
+    event_pattern = jsonencode({
+        detail-type = ["message"]
+    })
+}
+
+# Create CloudWatch Log Group
+
+resource "aws_cloudwatch_log_group" "example" {
+    name = "/aws/events/schedulerApplication"
+    retention_in_days = 1
+}
+
+data "aws_iam_policy_document" "example_log_policy" {
+  statement {
+    effect = "Allow"
+    actions = [
+      "logs:CreateLogStream"
+    ]
+
+    resources = [
+      "${aws_cloudwatch_log_group.example.arn}:*"
+    ]
+
+    principals {
+      type = "Service"
+      identifiers = [
+        "events.amazonaws.com",
+        "delivery.logs.amazonaws.com"
+      ]
+    }
+  }
+  statement {
+    effect = "Allow"
+    actions = [
+      "logs:PutLogEvents"
+    ]
+
+    resources = [
+      "${aws_cloudwatch_log_group.example.arn}:*:*"
+    ]
+
+    principals {
+      type = "Service"
+      identifiers = [
+        "events.amazonaws.com",
+        "delivery.logs.amazonaws.com"
+      ]
+    }
+
+    condition {
+      test     = "ArnEquals"
+      values   = [aws_cloudwatch_event_rule.rule.arn]
+      variable = "aws:SourceArn"
+    }
+  }
+}
+
+resource "aws_cloudwatch_log_resource_policy" "example" {
+  policy_document = data.aws_iam_policy_document.example_log_policy.json
+  policy_name     = "schedulerApplication-log-publishing-policy"
+}
+
+resource "aws_cloudwatch_event_target" "example" {
+  rule = aws_cloudwatch_event_rule.rule.name
+  arn  = aws_cloudwatch_log_group.example.arn
+  event_bus_name = aws_cloudwatch_event_bus.scheduler-custom-event-bus.name
+}
+
+
+# Create EventBridge Schedule
+
+resource "aws_scheduler_schedule" "eventbridge-schedule" {
+  name = "eventbridge-schedule"
+
+  flexible_time_window {
+    mode = "OFF"
+  }
+
+  schedule_expression = "rate(1 minutes)" # 
+  schedule_expression_timezone = "US/Eastern" # Default is UTC
+  description = "Rate schedule to EventBridge custom bus"
+
+  target {
+    arn = aws_cloudwatch_event_bus.scheduler-custom-event-bus.arn
+    role_arn = aws_iam_role.scheduler-role.arn
+
+    dead_letter_config {
+        arn = aws_sqs_queue.scheduler-dlq.arn
+    }
+
+    eventbridge_parameters {
+      detail_type = "message"
+      source = "scheduledEvents"
+    }
+
+    input = jsonencode(
+      {"msg": "Hello from EventBridge Scheduler!"}
+    )
+  }
+}
+
+resource "aws_iam_policy" "scheduler_policy" {
+  name = "scheduler_policy"
+
+  policy = jsonencode(
+    {
+        "Version": "2012-10-17",
+        "Statement": [
+            {
+                "Sid": "VisualEditor0",
+                "Effect": "Allow",
+                "Action": [
+                    "events:putEvents",
+                    "sqs:SendMessage"
+                ],
+                "Resource": "*"
+            }
+        ]
+    }
+  )
+}
+
+resource "aws_iam_role" "scheduler-role" {
+  name = "scheduler-role"
+  managed_policy_arns = [aws_iam_policy.scheduler_policy.arn]
+
+  assume_role_policy = jsonencode({
+    Version = "2012-10-17"
+    Statement = [
+      {
+        Action = "sts:AssumeRole"
+        Effect = "Allow"
+        Sid    = ""
+        Principal = {
+          Service = "scheduler.amazonaws.com"
+        }
+      },
+    ]
+  })
+}