feat: Hyperlane AVS contracts

.gitmodules

@@ -1,3 +1,9 @@
 [submodule "solidity/lib/forge-std"]
 	path = solidity/lib/forge-std
 	url = https://github.com/foundry-rs/forge-std
+[submodule "solidity/lib/eigenlayer-middleware"]
+	path = solidity/lib/eigenlayer-middleware
+	url = https://github.com/Layr-Labs/eigenlayer-middleware
+[submodule "solidity/lib/eigenlayer-contracts"]
+	path = solidity/lib/eigenlayer-contracts
+	url = https://github.com/Layr-Labs/eigenlayer-contracts

solidity/contracts/avs/ECDSAServiceManagerBase.sol

@@ -0,0 +1,145 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+import {OwnableUpgradeable} from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
+
+import {ISignatureUtils} from "@eigenlayer/interfaces/ISignatureUtils.sol";
+import {IAVSDirectory} from "@eigenlayer/interfaces/IAVSDirectory.sol";
+import {ISlasher} from "@eigenlayer/interfaces/ISlasher.sol";
+
+import {ECDSAStakeRegistry} from "@eigenlayer/middleware/unaudited/ECDSAStakeRegistry.sol";
+import {IServiceManager} from "@eigenlayer/middleware/interfaces/IServiceManager.sol";
+
+import {IRemoteChallenger} from "../interfaces/avs/IRemoteChallenger.sol";
+
+contract ECDSAServiceManagerBase is IServiceManager, OwnableUpgradeable {
+    event OperatorRegisteredToAVS(address indexed operator);
+    event OperatorDeregisteredToAVS(address indexed operator);
+
+    ECDSAStakeRegistry internal immutable stakeRegistry;
+    IAVSDirectory internal immutable elAvsDirectory;
+    ISlasher internal slasher;
+
+    /// @notice when applied to a function, only allows the ECDSAStakeRegistry to call it
+    modifier onlyStakeRegistry() {
+        require(
+            msg.sender == address(stakeRegistry),
+            "ECDSAServiceManagerBase: caller is not the stake registry"
+        );
+        _;
+    }
+
+    // ============ Constructor ============
+
+    constructor(
+        IAVSDirectory _avsDirectory,
+        ECDSAStakeRegistry _stakeRegistry,
+        ISlasher _slasher
+    ) {
+        elAvsDirectory = _avsDirectory;
+        stakeRegistry = _stakeRegistry;
+        slasher = _slasher;
+        _disableInitializers();
+    }
+
+    // ============ Public Functions ============
+
+    /**
+     * @notice Updates the metadata URI for the AVS
+     * @param _metadataURI is the metadata URI for the AVS
+     * @dev only callable by the owner
+     */
+    function updateAVSMetadataURI(
+        string memory _metadataURI
+    ) public virtual onlyOwner {
+        elAvsDirectory.updateAVSMetadataURI(_metadataURI);
+    }
+
+    /**
+     * @notice Forwards a call to EigenLayer's AVSDirectory contract to confirm operator registration with the AVS
+     * @param operator The address of the operator to register.
+     * @param operatorSignature The signature, salt, and expiry of the operator's signature.
+     */
+    function registerOperatorToAVS(
+        address operator,
+        ISignatureUtils.SignatureWithSaltAndExpiry memory operatorSignature
+    ) public virtual onlyStakeRegistry {
+        elAvsDirectory.registerOperatorToAVS(operator, operatorSignature);
+        emit OperatorRegisteredToAVS(operator);
+    }
+
+    /**
+     * @notice Forwards a call to EigenLayer's AVSDirectory contract to confirm operator deregistration from the AVS
+     * @param operator The address of the operator to deregister.
+     */
+    function deregisterOperatorFromAVS(
+        address operator
+    ) public virtual onlyStakeRegistry {
+        elAvsDirectory.deregisterOperatorFromAVS(operator);
+        emit OperatorDeregisteredToAVS(operator);
+    }
+
+    function freezeOperator(address operator) public virtual onlyOwner {
+        slasher.freezeOperator(operator);
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @notice Returns the list of strategies that the AVS supports for restaking
+     * @dev This function is intended to be called off-chain
+     * @dev No guarantee is made on uniqueness of each element in the returned array.
+     *      The off-chain service should do that validation separately
+     */
+    function getRestakeableStrategies()
+        external
+        view
+        returns (address[] memory)
+    {
+        return _getRestakeableStrategies();
+    }
+
+    /**
+     * @notice Returns the list of strategies that the operator has potentially restaked on the AVS
+     * @dev This function is intended to be called off-chain
+     * @dev Since ECDSAStakeRegistry only supports one quorum, each operator restakes into all the AVS strategies
+     * @dev No guarantee is made on uniqueness of each element in the returned array.
+     *      The off-chain service should do that validation separately
+     */
+    function getOperatorRestakedStrategies(
+        address /* operator */
+    ) external view returns (address[] memory) {
+        return _getRestakeableStrategies();
+    }
+
+    /// @notice Returns the EigenLayer AVSDirectory contract.
+    function avsDirectory() external view override returns (address) {
+        return address(elAvsDirectory);
+    }
+
+    // ============ Internal Function ============
+
+    function _getRestakeableStrategies()
+        internal
+        view
+        returns (address[] memory)
+    {
+        uint256 strategyCount = stakeRegistry.quorum().strategies.length;
+
+        if (strategyCount == 0) {
+            return new address[](0);
+        }
+
+        address[] memory restakedStrategies = new address[](strategyCount);
+        for (uint256 i = 0; i < strategyCount; i++) {
+            restakedStrategies[i] = address(
+                stakeRegistry.quorum().strategies[i].strategy
+            );
+        }
+        return restakedStrategies;
+    }
+
+    // storage gap for upgradeability
+    // slither-disable-next-line shadowing-state
+    uint256[50] private __GAP;
+}

solidity/contracts/avs/HyperlaneServiceManager.sol

@@ -0,0 +1,176 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+import "forge-std/console.sol";
+
+import {IAVSDirectory} from "@eigenlayer/interfaces/IAVSDirectory.sol";
+import {ISlasher} from "@eigenlayer/interfaces/ISlasher.sol";
+import {ECDSAStakeRegistry} from "@eigenlayer/middleware/unaudited/ECDSAStakeRegistry.sol";
+
+import {Enrollment, EnrollmentStatus, EnumerableMapEnrollment} from "../libs/EnumerableMapEnrollment.sol";
+import {IRemoteChallenger} from "../interfaces/avs/IRemoteChallenger.sol";
+import {ECDSAServiceManagerBase} from "./ECDSAServiceManagerBase.sol";
+
+contract HyperlaneServiceManager is ECDSAServiceManagerBase {
+    using EnumerableMapEnrollment for EnumerableMapEnrollment.AddressToEnrollmentMap;
+
+    event OperatorEnrolledToChallenger(
+        address operator,
+        IRemoteChallenger challenger
+    );
+    event OperatorQueuedUnenrollmentFromChallenger(
+        address operator,
+        IRemoteChallenger challenger,
+        uint256 unenrollmentStartBlock,
+        uint256 challengeDelayBlocks
+    );
+    event OperatorUnenrolledFromChallenger(
+        address operator,
+        IRemoteChallenger challenger,
+        uint256 unenrollmentEndBlock,
+        uint256 challengeDelayBlocks
+    );
+
+    mapping(address => EnumerableMapEnrollment.AddressToEnrollmentMap) enrolledChallengers;
+
+    modifier onlyEnrolledChallenger(address operator) {
+        (bool exists, ) = enrolledChallengers[operator].tryGet(msg.sender);
+        require(
+            exists,
+            "HyperlaneServiceManager: Operator not enrolled in challenger"
+        );
+        _;
+    }
+
+    // ============ Constructor ============
+
+    constructor(
+        IAVSDirectory _avsDirectory,
+        ECDSAStakeRegistry _stakeRegistry,
+        ISlasher _slasher
+    ) ECDSAServiceManagerBase(_avsDirectory, _stakeRegistry, _slasher) {}
+
+    // ============ Public Functions ============
+
+    /**
+     * @notice Forwards a call to EigenLayer's AVSDirectory contract to confirm operator deregistration from the AVS
+     * @param operator The address of the operator to deregister.
+     */
+    function deregisterOperatorFromAVS(
+        address operator
+    ) public virtual override onlyStakeRegistry {
+        address[] memory challengers = getOperatorChallengers(operator);
+        for (uint256 i = 0; i < challengers.length; i++) {
+            IRemoteChallenger challenger = IRemoteChallenger(challengers[i]);
+            Enrollment memory enrollment = enrolledChallengers[operator].get(
+                challengers[i]
+            );
+            require(
+                enrollment.status != EnrollmentStatus.ENROLLED,
+                string(
+                    abi.encodePacked(
+                        "HyperlaneServiceManager: Operator still enrolled in challenger",
+                        challengers[i]
+                    )
+                )
+            );
+            enrolledChallengers[operator].remove(challengers[i]);
+        }
+        elAvsDirectory.deregisterOperatorFromAVS(operator);
+    }
+
+    // ============ External Functions ============
+
+    function enrollIntoChallengers(
+        IRemoteChallenger[] memory _challengers
+    ) external {
+        for (uint256 i = 0; i < _challengers.length; i++) {
+            IRemoteChallenger challenger = _challengers[i];
+            enrolledChallengers[msg.sender].set(
+                address(challenger),
+                Enrollment(EnrollmentStatus.ENROLLED, 0)
+            );
+            emit OperatorEnrolledToChallenger(msg.sender, challenger);
+        }
+    }
+
+    function queueUnenrollmentFromChallengers(
+        IRemoteChallenger[] memory _challengers
+    ) external {
+        for (uint256 i = 0; i < _challengers.length; i++) {
+            IRemoteChallenger challenger = _challengers[i];
+            (bool exists, Enrollment memory enrollment) = enrolledChallengers[
+                msg.sender
+            ].tryGet(address(challenger));
+            console.log(
+                "queueUnenrollmentFromChallengers",
+                exists,
+                uint8(enrollment.status)
+            );
+            if (exists && enrollment.status == EnrollmentStatus.ENROLLED) {
+                enrolledChallengers[msg.sender].set(
+                    address(challenger),
+                    Enrollment(
+                        EnrollmentStatus.PENDING_UNENROLLMENT,
+                        uint248(block.number)
+                    )
+                );
+                emit OperatorQueuedUnenrollmentFromChallenger(
+                    msg.sender,
+                    challenger,
+                    block.number,
+                    challenger.challengeDelayBlocks()
+                );
+            }
+        }
+    }
+
+    function completeQueuedUnenrollmentFromChallengers(
+        IRemoteChallenger[] memory _challengers
+    ) external {
+        for (uint256 i = 0; i < _challengers.length; i++) {
+            IRemoteChallenger challenger = _challengers[i];
+            (bool exists, Enrollment memory enrollment) = enrolledChallengers[
+                msg.sender
+            ].tryGet(address(challenger));
+            if (
+                exists &&
+                enrollment.status == EnrollmentStatus.PENDING_UNENROLLMENT &&
+                block.number >=
+                enrollment.unenrollmentStartBlock +
+                    challenger.challengeDelayBlocks()
+            ) {
+                enrolledChallengers[msg.sender].remove(address(challenger));
+                emit OperatorUnenrolledFromChallenger(
+                    msg.sender,
+                    challenger,
+                    block.number,
+                    challenger.challengeDelayBlocks()
+                );
+            }
+        }
+    }
+
+    function freezeOperator(
+        address operator
+    ) public virtual override onlyEnrolledChallenger(operator) {
+        slasher.freezeOperator(operator);
+    }
+
+    function getEnrolledChallenger(
+        address _operator,
+        IRemoteChallenger _challenger
+    ) external view returns (Enrollment memory enrollment) {
+        address[] memory keys = enrolledChallengers[_operator].keys();
+        for (uint256 i = 0; i < keys.length; i++) {
+            console.log("key", keys[i], address(_challenger));
+        }
+        return enrolledChallengers[_operator].get(address(_challenger));
+    }
+
+    function getOperatorChallengers(
+        address _operator
+    ) public view returns (address[] memory) {
+        return enrolledChallengers[_operator].keys();
+    }
+}

solidity/contracts/interfaces/avs/IRemoteChallenger.sol

@@ -0,0 +1,19 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+interface IRemoteChallenger {
+    function challengeDelayBlocks() external view returns (uint256);
+    function handleChallenge(address operator) external;
+}