build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven { url = "https://maven.minecraftforge.net" }
    }
    dependencies {
        classpath "com.anatawa12.forge:ForgeGradle:2.3-1.0.7"
    }
}
apply plugin: "net.minecraftforge.gradle.forge"


version = "1.12.2-0.6.1"
group = "com.charles445.simpledifficulty" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "SimpleDifficulty"

sourceCompatibility = targetCompatibility = '1.8' // Need this here so eclipse task generates correctly.
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
    version = "1.12.2-14.23.5.2847"
    runDir = "run"
    mappings = "stable_39"
    // makeObfSourceJar = false // an Srg named sources jar is made by default. uncomment this to disable.
}

repositories {
    mavenCentral()
    maven {
        name = "CurseForge"
        url "https://www.cursemaven.com"
    }
    maven {
        name = "Fluidlogged API"
        url 'https://jitpack.io'
    }
}

dependencies {
    // Streams
    deobfCompile "curse.maven:streams-229769:3109315"
    deobfCompile "curse.maven:farseek-229708:3093852"

    // Serene Seasons
    compileOnly "curse.maven:sereneseasons-291874:2799213"

    // Dynamic Trees
    compileOnly "curse.maven:DynamicTrees-252818:3812473"

    // Fluidlogged API
    compileOnly "com.github.jbredwards:fluidlogged-api:2573e41f3e"
}

processResources{
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
    
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

task apiJar(type: Jar){
	from(sourceSets.main.allJava){
		include 'com/charles445/simpledifficulty/api/**'
	}
	
	classifier = 'api'
}

artifacts {
	archives apiJar
}

jar {
    manifest 
	{
        attributes "FMLCorePlugin": "com.charles445.simpledifficulty.asm.CoreLoader"
		attributes "FMLCorePluginContainsFMLMod": "com.charles445.simpledifficulty.SimpleDifficulty"
    }
}