Confirm Websocket pong frames are received by handlers

test/handlers/ws_ping_h.erl

@@ -0,0 +1,23 @@
+%% This module sends an empty ping to the client and
+%% waits for a pong before sending a text frame. It
+%% is used to confirm server-initiated pings work.
+
+-module(ws_ping_h).
+-behavior(cowboy_websocket).
+
+-export([init/2]).
+-export([websocket_init/1]).
+-export([websocket_handle/2]).
+-export([websocket_info/2]).
+
+init(Req, _) ->
+	{cowboy_websocket, Req, undefined}.
+
+websocket_init(State) ->
+	{[{ping, <<>>}], State}.
+
+websocket_handle(pong, State) ->
+	{[{text, <<"OK!!">>}], State}.
+
+websocket_info(_, State) ->
+	{[], State}.

test/ws_SUITE.erl

@@ -68,7 +68,8 @@ init_dispatch() ->
 			{"/ws_timeout_cancel", ws_timeout_cancel, []},
 			{"/ws_max_frame_size", ws_max_frame_size, []},
 			{"/ws_deflate_opts", ws_deflate_opts_h, []},
-			{"/ws_dont_validate_utf8", ws_dont_validate_utf8_h, []}
+			{"/ws_dont_validate_utf8", ws_dont_validate_utf8_h, []},
+			{"/ws_ping", ws_ping_h, []}
 		]}
 	]).
 
@@ -472,6 +473,17 @@ ws_max_frame_size_intermediate_fragment_close(Config) ->
 	{error, closed} = gen_tcp:recv(Socket, 0, 6000),
 	ok.
 
+ws_ping(Config) ->
+	doc("Server initiated pings can receive a pong in response."),
+	{ok, Socket, _} = do_handshake("/ws_ping", Config),
+	%% Receive a server-sent ping.
+	{ok, << 1:1, 0:3, 9:4, 0:1, 0:7 >>} = gen_tcp:recv(Socket, 0, 6000),
+	%% Send a pong back with a 0 mask.
+	ok = gen_tcp:send(Socket, << 1:1, 0:3, 10:4, 1:1, 0:7, 0:32 >>),
+	%% Receive a text frame as a result.
+	{ok, << 1:1, 0:3, 1:4, 0:1, 4:7, "OK!!" >>} = gen_tcp:recv(Socket, 0, 6000),
+	ok.
+
 ws_send_close(Config) ->
 	doc("Server-initiated close frame ends the connection."),
 	{ok, Socket, _} = do_handshake("/ws_send_close", Config),